Viatrix/fee handler (#519)

* WIP: Basic FeeHandler

* WIP: Basic FeeHandler

* Fee handler with oracle

* FeeHandler: fixes after comments

* Fix after review

* Simplify abi decoding

* Added expiration time to oracle data

* sign oracle message by ethers.js

* Remove prefix from signature

* Add FeeCollected event

* Add FeeDistributed event

Co-authored-by: Oleksii Matiiasevych <lastperson@gmail.com>
Co-authored-by: Kirill <pisarevkir@gmail.com>

Author: 3 people

contracts/Bridge.sol

@@ -8,6 +8,7 @@ import "./utils/SafeCast.sol";
 import "./interfaces/IDepositExecute.sol";
 import "./interfaces/IERCHandler.sol";
 import "./interfaces/IGenericHandler.sol";
+import "./interfaces/IFeeHandler.sol";
 
 /**
     @title Facilitates deposits, creation and voting of deposit proposals, and deposit executions.
@@ -21,9 +22,10 @@ contract Bridge is Pausable, AccessControl, SafeMath {
 
     uint8   public _domainID;
     uint8   public _relayerThreshold;
-    uint128 public _fee;
     uint40  public _expiry;
 
+    IFeeHandler public _feeHandler;
+
     enum ProposalStatus {Inactive, Active, Passed, Executed, Cancelled}
 
     struct Proposal {
@@ -45,6 +47,7 @@ contract Bridge is Pausable, AccessControl, SafeMath {
     event RelayerThresholdChanged(uint256 newThreshold);
     event RelayerAdded(address relayer);
     event RelayerRemoved(address relayer);
+    event FeeHandlerChanged(address newFeeHandler);
     event Deposit(
         uint8   destinationDomainID,
         bytes32 resourceID,
@@ -125,10 +128,9 @@ contract Bridge is Pausable, AccessControl, SafeMath {
         @param initialRelayers Addresses that should be initially granted the relayer role.
         @param initialRelayerThreshold Number of votes needed for a deposit proposal to be considered passed.
      */
-    constructor (uint8 domainID, address[] memory initialRelayers, uint256 initialRelayerThreshold, uint256 fee, uint256 expiry) public {
+    constructor (uint8 domainID, address[] memory initialRelayers, uint256 initialRelayerThreshold, uint256 expiry) public {
         _domainID = domainID;
         _relayerThreshold = initialRelayerThreshold.toUint8();
-        _fee = fee.toUint128();
         _expiry = expiry.toUint40();
 
         _setupRole(DEFAULT_ADMIN_ROLE, _msgSender());
@@ -315,13 +317,13 @@ contract Bridge is Pausable, AccessControl, SafeMath {
     }
 
     /**
-        @notice Changes deposit fee.
+        @notice Changes deposit fee handler contract address.
         @notice Only callable by admin.
-        @param newFee Value {_fee} will be updated to.
+        @param newFeeHandler Address {_feeHandler} will be updated to.
      */
-    function adminChangeFee(uint256 newFee) external onlyAdmin {
-        require(_fee != newFee, "Current fee is equal to new fee");
-        _fee = newFee.toUint128();
+    function adminChangeFeeHandler(address newFeeHandler) external onlyAdmin {
+        _feeHandler = IFeeHandler(newFeeHandler);
+        emit FeeHandlerChanged(newFeeHandler);
     }
 
     /**
@@ -342,25 +344,31 @@ contract Bridge is Pausable, AccessControl, SafeMath {
         @notice Only callable when Bridge is not paused.
         @param destinationDomainID ID of chain deposit will be bridged to.
         @param resourceID ResourceID used to find address of handler to be used for deposit.
-        @param data Additional data to be passed to specified handler.
+        @param depositData Additional data to be passed to specified handler.
+        @param feeData Additional data to be passed to the fee handler.
         @notice Emits {Deposit} event with all necessary parameters and a handler response.
         - ERC20Handler: responds with an empty data.
         - ERC721Handler: responds with the deposited token metadata acquired by calling a tokenURI method in the token contract.
         - GenericHandler: responds with the raw bytes returned from the call to the target contract.
      */
-    function deposit(uint8 destinationDomainID, bytes32 resourceID, bytes calldata data) external payable whenNotPaused {
-        require(msg.value == _fee, "Incorrect fee supplied");
+    function deposit(uint8 destinationDomainID, bytes32 resourceID, bytes calldata depositData, bytes calldata feeData) external payable whenNotPaused {
+        address sender = _msgSender();
+        if (address(_feeHandler) == address(0)) {
+            require(msg.value == 0, "no FeeHandler, msg.value != 0");
+        } else {
+            // Reverts on failure
+            _feeHandler.collectFee{value: msg.value}(sender, _domainID, destinationDomainID, resourceID, depositData, feeData);
+        }
 
         address handler = _resourceIDToHandlerAddress[resourceID];
         require(handler != address(0), "resourceID not mapped to handler");
 
         uint64 depositNonce = ++_depositCounts[destinationDomainID];
-        address sender = _msgSender();
 
         IDepositExecute depositHandler = IDepositExecute(handler);
-        bytes memory handlerResponse = depositHandler.deposit(resourceID, sender, data);
+        bytes memory handlerResponse = depositHandler.deposit(resourceID, sender, depositData);
 
-        emit Deposit(destinationDomainID, resourceID, depositNonce, sender, data, handlerResponse);
+        emit Deposit(destinationDomainID, resourceID, depositNonce, sender, depositData, handlerResponse);
     }
 
     /**
@@ -489,16 +497,4 @@ contract Bridge is Pausable, AccessControl, SafeMath {
 
         emit ProposalEvent(domainID, depositNonce, ProposalStatus.Executed, dataHash);
     }
-
-    /**
-        @notice Transfers eth in the contract to the specified addresses. The parameters addrs and amounts are mapped 1-1.
-        This means that the address at index 0 for addrs will receive the amount (in WEI) from amounts at index 0.
-        @param addrs Array of addresses to transfer {amounts} to.
-        @param amounts Array of amonuts to transfer to {addrs}.
-     */
-    function transferFunds(address payable[] calldata addrs, uint[] calldata amounts) external onlyAdmin {
-        for (uint256 i = 0; i < addrs.length; i++) {
-            addrs[i].transfer(amounts[i]);
-        }
-    }
 }

contracts/handlers/fee/BasicFeeHandler.sol

@@ -0,0 +1,95 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+pragma solidity 0.8.11;
+pragma experimental ABIEncoderV2;
+
+import "../../interfaces/IFeeHandler.sol";
+import "../../utils/AccessControl.sol";
+
+/**
+    @title Handles deposit fees.
+    @author ChainSafe Systems.
+    @notice This contract is intended to be used with the Bridge contract.
+ */
+contract BasicFeeHandler is IFeeHandler, AccessControl {
+    address public immutable _bridgeAddress;
+
+    uint256 public _fee;
+
+    event FeeChanged(
+        uint256 newFee
+    );
+
+    modifier onlyBridge() {
+        _onlyBridge();
+        _;
+    }
+
+    function _onlyBridge() private view {
+        require(msg.sender == _bridgeAddress, "sender must be bridge contract");
+    }
+
+    /**
+        @param bridgeAddress Contract address of previously deployed Bridge.
+     */
+    constructor(address bridgeAddress) public {
+        _bridgeAddress = bridgeAddress;
+        _setupRole(DEFAULT_ADMIN_ROLE, msg.sender);
+    }
+
+    /**
+        @notice Collects fee for deposit.
+        @param sender Sender of the deposit.
+        @param destinationDomainID ID of chain deposit will be bridged to.
+        @param resourceID ResourceID to be used when making deposits.
+        @param depositData Additional data to be passed to specified handler.
+        @param feeData Additional data to be passed to the fee handler.
+     */
+    function collectFee(address sender, uint8 fromDomainID, uint8 destinationDomainID, bytes32 resourceID, bytes calldata depositData, bytes calldata feeData) payable external onlyBridge {
+        require(msg.value == _fee, "Incorrect fee supplied");
+        emit FeeCollected(sender, fromDomainID, destinationDomainID, resourceID, _fee, address(0));
+    }
+
+     /**
+        @notice Calculates fee for deposit.
+        @param sender Sender of the deposit.
+        @param destinationDomainID ID of chain deposit will be bridged to.
+        @param resourceID ResourceID to be used when making deposits.
+        @param depositData Additional data to be passed to specified handler.
+        @param feeData Additional data to be passed to the fee handler.
+        @return Returns the fee amount.
+     */
+    function calculateFee(address sender, uint8 fromDomainID, uint8 destinationDomainID, bytes32 resourceID, bytes calldata depositData, bytes calldata feeData) external view returns(uint256, address) {
+        return (_fee, address(0));
+    }
+
+    /**
+        @notice Sets new value of the fee.
+        @notice Only callable by admin.
+        @param newFee Value {_fee} will be updated to.
+     */
+    function changeFee(uint256 newFee) external onlyAdmin {
+        require(_fee != newFee, "Current fee is equal to new fee");
+        _fee = newFee;
+        emit FeeChanged(newFee);
+    }
+
+    /**
+        @notice Transfers eth in the contract to the specified addresses. The parameters addrs and amounts are mapped 1-1.
+        This means that the address at index 0 for addrs will receive the amount (in WEI) from amounts at index 0.
+        @param addrs Array of addresses to transfer {amounts} to.
+        @param amounts Array of amonuts to transfer to {addrs}.
+     */
+    function transferFee(address payable[] calldata addrs, uint[] calldata amounts) external onlyAdmin {
+        require(addrs.length == amounts.length, "addrs[], amounts[]: diff length");
+        for (uint256 i = 0; i < addrs.length; i++) {
+            (bool success,) = addrs[i].call{value: amounts[i]}("");
+            require(success, "Fee ether transfer failed");
+            emit FeeDistributed(address(0), addrs[i], amounts[i]);
+        }
+    }
+
+    modifier onlyAdmin() {
+        require(hasRole(DEFAULT_ADMIN_ROLE, msg.sender), "sender doesn't have admin role");
+        _;
+    }
+}