CloudWatchLogGroupChecker/main.tf at main · Fraham/CloudWatchLogGroupChecker · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
provider "aws" {
  region = "eu-west-1"
}

variable "bucket" {
}
variable "app_version" {
}
variable "notification_topic" {
  type    = string
  default = ""
}
variable "cloud_watch_alarm_topic" {
  type    = string
  description = "The SNS topic for CloudWatch alarms"
  default = ""
}

data "aws_caller_identity" "current" {}

resource "aws_lambda_function" "log_group_checker" {
  function_name = "LogGroupChecker"

  s3_bucket = var.bucket
  s3_key    = "v${var.app_version}/code.zip"

  handler = "logGroupChecker.handler"
  runtime = "nodejs12.x"

  role = aws_iam_role.log_group_checker_exec.arn

  layers = [aws_lambda_layer_version.dependencies.arn]

  tracing_config {
    mode = "Active"
  }

  timeout = 30

  environment {
    variables = {
      NOTIFICATION_TOPIC = var.notification_topic,
      PARAMETER_NAME     = aws_ssm_parameter.maximum_retention_period.name
    }
  }
}

resource "aws_lambda_layer_version" "dependencies" {
  layer_name = "Dependencies"
  s3_bucket  = var.bucket
  s3_key     = "v${var.app_version}/dependencies.zip"
}

resource "aws_iam_role" "log_group_checker_exec" {
  name = "log_group_checker_lambda_role"

  assume_role_policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": "sts:AssumeRole",
      "Principal": {
        "Service": "lambda.amazonaws.com"
      },
      "Effect": "Allow",
      "Sid": ""
    }
  ]
}
EOF

}

resource "aws_iam_policy" "log_group_checker_logging" {
  name        = "log_group_checker_logging"
  path        = "/"
  description = "IAM policy for logging from a lambda"

  policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": [
        "logs:ListTagsLogGroup",
        "logs:CreateLogStream",
        "logs:DescribeLogGroups",
        "logs:DeleteRetentionPolicy",
        "logs:PutRetentionPolicy",
        "logs:CreateLogGroup",
        "logs:PutLogEvents"
      ],
      "Resource": "arn:aws:logs:*:${data.aws_caller_identity.current.account_id}:log-group:*",
      "Effect": "Allow"
    },
    {
      "Action": [
        "sns:Publish"
      ],
      "Resource":"${var.notification_topic == "" ? "*" : var.notification_topic}",
      "Effect": "Allow"
    },
    {
      "Action": [
        "ssm:GetParameter"
      ],
      "Resource":"${aws_ssm_parameter.maximum_retention_period.arn}",
      "Effect": "Allow"
    }
  ]
}
EOF
}

resource "aws_iam_role_policy_attachment" "log_group_checker_logs" {
  role       = aws_iam_role.log_group_checker_exec.name
  policy_arn = aws_iam_policy.log_group_checker_logging.arn
}

resource "aws_iam_role_policy_attachment" "aws_xray_write_only_access" {
  role       = aws_iam_role.log_group_checker_exec.name
  policy_arn = "arn:aws:iam::aws:policy/AWSXrayWriteOnlyAccess"
}

resource "aws_ssm_parameter" "maximum_retention_period" {
  name        = "/LogGroupChecker/maximumRetentionPeriod"
  description = "Maximum retention period for CloudWatch Log Groups, used in LogGroupChecker."
  type        = "String"
  value       = 3
  overwrite   = true
}

module "log_group_checker_lambda_alarms" {
  source = "github.com/Fraham/TerraformModuleForAws//modules/services/lambda/alarms"

  function_name = aws_lambda_function.log_group_checker.function_name
  cloud_watch_alarm_topic = var.cloud_watch_alarm_topic
}

module "check_schedule" {
  source = "github.com/Fraham/TerraformModuleForAws//modules/services/lambda/schedule"

  function_name = aws_lambda_function.log_group_checker.function_name
  function_arn = aws_lambda_function.log_group_checker.arn
  schedule_expression = "rate(1 day)"
}