build.gradle

plugins {
    id 'java'
    id 'com.gradleup.shadow' version '9.3.1'
}

group = project.mod_group
version = project.mod_version

// ---------------------------------------------------------------------------
// Hytale Maven version resolution
// Fetches the latest release from maven.hytale.com at build time.
// Use -Phytale_channel=pre-release  (or run ./gradlew buildPreRelease)
// to target the pre-release channel instead.
// ---------------------------------------------------------------------------
def resolveHytaleVersion(String channel) {
    def url = "https://maven.hytale.com/${channel}/com/hypixel/hytale/Server/maven-metadata.xml"
    def text = new URL(url).text
    def matcher = text =~ /<release>(.+?)<\/release>/
    if (!matcher.find()) throw new GradleException("Could not resolve Hytale server version from ${url}")
    return matcher.group(1)
}

def hytaleChannel = project.findProperty('hytale_channel') ?: 'release'
def hytaleVersion = resolveHytaleVersion(hytaleChannel)

// Shared version property avoids accessing project at execution time
def buildVersion = objects.property(String).convention(version)

// Override version for dev builds
gradle.taskGraph.whenReady { graph ->
    if (graph.hasTask(':buildDev')) {
        project.version = '0.0.0'
        buildVersion.set('0.0.0')
    }
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(project.java_version.toInteger())
    }
}

repositories {
    mavenCentral()
    maven { url "https://maven.hytale.com/${hytaleChannel}" }
    // PlaceholderAPI for Hytale
    maven { url = 'https://repo.helpch.at/releases/' }
}

dependencies {
    // Hytale Server API — resolved automatically from maven.hytale.com
    compileOnly "com.hypixel.hytale:Server:${hytaleVersion}"

    // Note: HyFactions is a soft dependency using pure reflection
    // No compile-time dependency needed - just runtime class detection

    // JSON handling
    implementation 'com.google.code.gson:gson:2.11.0'

    // High-performance caching (L1 cache)
    implementation 'com.github.ben-manes.caffeine:caffeine:3.1.8'

    // YAML parsing (for LuckPerms migration)
    implementation 'org.yaml:snakeyaml:2.2'

    // Database - HikariCP connection pooling
    implementation 'com.zaxxer:HikariCP:6.2.1'

    // Database - SQLite JDBC driver (optional - user must download separately)
    // The driver is NOT bundled to keep JAR size small (~4MB vs ~15MB)
    // Users who want SQLite features must download the JAR to plugins/HyperPerms/lib/
    compileOnly 'org.xerial:sqlite-jdbc:3.45.1.0'

    // Database - MariaDB JDBC driver
    implementation 'org.mariadb.jdbc:mariadb-java-client:3.5.1'

    // Redis client for pub/sub and L2 cache (P5 - deferred)
    // implementation 'io.lettuce:lettuce-core:6.5.2.RELEASE'

    // Null safety annotations
    compileOnly 'org.jetbrains:annotations:26.0.1'

    // VaultUnlocked API (soft dependency - compileOnly)
    compileOnly files('libs/VaultUnlocked-Hytale-2.19.0.jar')

    // PlaceholderAPI Hytale (soft dependency - compileOnly)
    compileOnly 'at.helpch:placeholderapi-hytale:1.0.4'

    // Testing
    testImplementation 'org.junit.jupiter:junit-jupiter:5.11.4'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher:1.11.4'
}

// Generate BuildInfo.java with project version
def generatedSrcDir = layout.buildDirectory.dir("generated/sources/buildinfo/java")
sourceSets.main.java.srcDir(generatedSrcDir)

tasks.register('generateBuildInfo') {
    def outputDir = generatedSrcDir
    def ver = buildVersion
    inputs.property('version', ver)
    outputs.dir(outputDir)
    doLast {
        def v = ver.get()
        def dir = outputDir.get().asFile.toPath().resolve("com/hyperperms").toFile()
        dir.mkdirs()
        new File(dir, "BuildInfo.java").text = """\
package com.hyperperms;

/**
 * Auto-generated build information.
 */
public final class BuildInfo {
    public static final String VERSION = "${v}";
    public static final String JAVA_VERSION = "${System.getProperty('java.version')}";
    public static final long BUILD_TIMESTAMP = ${System.currentTimeMillis()}L;
    private BuildInfo() {}
}
"""
    }
}

tasks.named('compileJava') {
    dependsOn 'generateBuildInfo'
}

// Expand version placeholders in manifest.json
processResources {
    def ver = buildVersion
    inputs.property('version', ver)
    inputs.property('serverVersion', hytaleVersion)
    filesMatching('manifest.json') {
        expand(version: ver.get(), serverVersion: hytaleVersion)
    }
}

// Prevent the plain jar task from overwriting the shadow JAR
// (both default to empty classifier; in multi-project builds the jar task
// runs after shadowJar for project dependencies and would clobber it)
jar {
    archiveClassifier = 'plain'
}

shadowJar {
    archiveClassifier.set('')

    // Relocate dependencies to avoid conflicts
    relocate 'com.google.gson', 'com.hyperperms.lib.gson'
    relocate 'com.github.benmanes.caffeine', 'com.hyperperms.lib.caffeine'
    relocate 'org.yaml.snakeyaml', 'com.hyperperms.lib.snakeyaml'
    // Note: SQLite JDBC cannot be relocated due to native library loading
    relocate 'com.zaxxer.hikari', 'com.hyperperms.lib.hikari'
    // Note: MariaDB JDBC is NOT relocated because the shadow plugin does not
    // rewrite META-INF/services files, breaking the driver's internal
    // ServiceLoader-based plugin discovery (auth plugins, codecs, etc.).

    // Future relocations:
    // relocate 'io.lettuce', 'com.hyperperms.lib.lettuce'
}

test {
    useJUnitPlatform()

    // Enable virtual threads for tests (Java 21+)
    jvmArgs '--enable-preview'

    testLogging {
        events 'passed', 'skipped', 'failed'
        showStandardStreams = true
    }
}

build {
    dependsOn shadowJar
}

// ---------------------------------------------------------------------------
// Build tasks
// ---------------------------------------------------------------------------
tasks.register('buildDev') {
    group = 'build'
    description = 'Clean build with dev version identifier'
    dependsOn 'clean', 'build'
}

tasks.named('build') {
    mustRunAfter 'clean'
}

tasks.register('buildRelease', GradleBuild) {
    group       = 'build'
    description = 'Clean build against the latest Hytale release server'
    tasks       = ['clean', 'shadowJar']
    startParameter.projectProperties = ['hytale_channel': 'release']
}

tasks.register('buildPreRelease', GradleBuild) {
    group       = 'build'
    description = 'Clean build against the latest Hytale pre-release server'
    tasks       = ['clean', 'shadowJar']
    startParameter.projectProperties = ['hytale_channel': 'pre-release']
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.compilerArgs.addAll([
        '-Xlint:all',
        '-Xlint:-processing',
        '--enable-preview'
    ])
}