ForgeDevPlugin/settings.gradle at FD_7.0 · MinecraftForge/ForgeDevPlugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
plugins {
    id 'org.gradle.toolchains.foojay-resolver-convention' version '1.0.0'
}

rootProject.name = 'forgedev'

// Applying plugins causes them to not have any IDE support when also applied to any build.gradle files
// The workaround for now is to use this listener here so that it can stay in settings.gradle
// See: https://youtrack.jetbrains.com/issue/IDEA-332061/Gradle-Missing-Code-Completion-Suggestions-for-Settings-Plugins-in-Groovy-DSL
gradle.beforeProject { Project project ->
    project.pluginManager.withPlugin('net.minecraftforge.gradleutils') {
        project.repositories {
            mavenCentral()
            gradlePluginPortal()
            maven project.gradleutils.forgeMaven
            //mavenLocal()
        }
    }
}

//@formatter:off
dependencyResolutionManagement.versionCatalogs.register('libs') {
    version 'gradleutils', '3.4.4'

    plugin 'licenser',       'net.minecraftforge.licenser'    version '1.2.0'
    plugin 'gradleutils',    'net.minecraftforge.gradleutils' versionRef 'gradleutils'
    plugin 'gitversion',     'net.minecraftforge.gitversion'  version '3.1.6'
    plugin 'changelog',      'net.minecraftforge.changelog'   version '3.1.3'
    plugin 'shadow',         'com.gradleup.shadow'            version '9.2.2'

    // Static Analysis
    library 'nulls', 'org.jetbrains', 'annotations' version '26.0.2-1'

    // Gradle API
    version 'gradle', '9.2.0'
    library 'gradle', 'name.remal.gradle-api', 'gradle-api'  versionRef 'gradle'

    // GradleUtils Shared Base
    library 'gradleutils-shared', 'net.minecraftforge', 'gradleutils-shared' versionRef 'gradleutils'

    // Plugins
    library 'gradle-download', 'de.undercouch.download', 'de.undercouch.download.gradle.plugin' version '5.6.0'

    version 'asm', '9.8'
    library 'asm',      'org.ow2.asm', 'asm'      versionRef 'asm'
    library 'asm-tree', 'org.ow2.asm', 'asm-tree' versionRef 'asm'
    bundle 'asm', ['asm', 'asm-tree']

    library 'srgutils',       'net.minecraftforge', 'srgutils'       version '0.5.14'
    library 'fastcsv',        'de.siegmar',         'fastcsv'        version '3.7.0'
    library 'jarjar',         'net.minecraftforge', 'JarJarMetadata' version '0.4.2'
    library 'maven-artifact', 'org.apache.maven',   'maven-artifact' version '3.8.8'

    library 'utils-data',     'net.minecraftforge', 'json-data-utils' version '0.4.1'  // https://files.minecraftforge.net/net/minecraftforge/json-data-utils/index.html
    library 'utils-hash',     'net.minecraftforge', 'hash-utils'      version '0.1.12' // https://files.minecraftforge.net/net/minecraftforge/hash-utils/index.html
    library 'utils-download', 'net.minecraftforge', 'download-utils'  version '0.4.0'  // https://files.minecraftforge.net/net/minecraftforge/download-utils/index.html
    library 'utils-files',    'net.minecraftforge', 'file-utils'      version '0.3.2'  // https://files.minecraftforge.net/net/minecraftforge/file-utils/index.html
    library 'utils-os',       'net.minecraftforge', 'os-utils'        version '0.1.0'  // https://files.minecraftforge.net/net/minecraftforge/os-utils/index.html
    bundle 'utils', ['utils-data', 'utils-hash', 'utils-download', 'utils-files', 'utils-os']
}
//@formatter:on