diff --git a/BaselineOfDebuggingSpy/BaselineOfDebuggingSpy.class.st b/BaselineOfDebuggingSpy/BaselineOfDebuggingSpy.class.st
index 7d92234..3f90c67 100644
--- a/BaselineOfDebuggingSpy/BaselineOfDebuggingSpy.class.st
+++ b/BaselineOfDebuggingSpy/BaselineOfDebuggingSpy.class.st
@@ -9,15 +9,14 @@ Class {
 BaselineOfDebuggingSpy >> baseline: spec [
 
 	<baseline>
-	
-	spec baseline: 'ExperimentModel' with: [ 
-		spec repository:
-			'github://Pharo-XP-Tools/ExperimentModel:main' ].
-	
-	spec for: #common do: [ 
-		spec postLoadDoIt: #postloadAction.
-		spec package: 'DebuggingSpy'.
-		spec package: 'DebuggingSpy-Tests' ]
+	spec baseline: 'ExperimentModel' with: [ spec repository: 'github://Pharo-XP-Tools/ExperimentModel:main' ].
+
+	spec for: #common do: [
+			spec postLoadDoIt: #postloadAction.
+			spec package: 'DebuggingSpy'.
+			spec package: 'DebuggingSpy-Tests'.
+			spec package: 'DebuggingSpy-Browser'.
+			spec package: 'DebuggingSpy-Browser-Tests' ]
 ]
 
 { #category : 'baselines' }
diff --git a/DebuggingSpy-Browser-Tests/DSRecordBrowserPresenterTest.class.st b/DebuggingSpy-Browser-Tests/DSRecordBrowserPresenterTest.class.st
new file mode 100644
index 0000000..5dc18e3
--- /dev/null
+++ b/DebuggingSpy-Browser-Tests/DSRecordBrowserPresenterTest.class.st
@@ -0,0 +1,303 @@
+Class {
+	#name : 'DSRecordBrowserPresenterTest',
+	#superclass : 'TestCase',
+	#instVars : [
+		'browser'
+	],
+	#category : 'DebuggingSpy-Browser-Tests',
+	#package : 'DebuggingSpy-Browser-Tests'
+}
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenterTest >> filesPresenter [
+
+	^ browser presenterAt: #fileListPresenter
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenterTest >> generateRecordsFile [
+	"Generates a file of random records and returns its file reference."
+
+	| records recordFileRef writeStream |
+	records := self getRecordExamples.
+
+	recordFileRef := self temporaryDirectory / ('ds-spy-test-' , UUID new asString).
+	recordFileRef ensureCreateFile.
+	writeStream := recordFileRef writeStream.
+
+	writeStream nextPut: $[.
+
+	records doWithIndex: [ :record :index |
+			writeStream nextPutAll: (STON toString: record).
+
+			index = records size ifFalse: [
+					writeStream nextPut: $,.
+					writeStream crlf ] ].
+
+	writeStream nextPut: $].
+
+	writeStream close.
+
+	^ recordFileRef
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenterTest >> getRecordExamples [
+
+	^ OrderedCollection new
+		  add: (DSBrowseRecord new
+				   windowId: 1;
+				   dateTime: (DateAndTime fromSeconds: 1);
+				   yourself);
+		  add: (DSMouseEnterWindowRecord new
+				   windowId: 2;
+				   dateTime: (DateAndTime fromSeconds: 2);
+				   yourself);
+		  add: (DSMouseLeaveWindowRecord new
+				   windowId: 3;
+				   dateTime: (DateAndTime fromSeconds: 3);
+				   yourself);
+		  add: (DSInspectItRecord new
+				   windowId: 4;
+				   dateTime: (DateAndTime fromSeconds: 4);
+				   yourself);
+		  yourself
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenterTest >> recordsFilterPresenter [
+
+	^ browser presenterAt: #recordsFilter
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenterTest >> recordsTablePresenter [
+
+	^ browser presenterAt: #recordsTablePresenter
+]
+
+{ #category : 'running' }
+DSRecordBrowserPresenterTest >> setUp [
+
+	super setUp.
+	browser := DSRecordBrowserPresenter new
+]
+
+{ #category : 'running' }
+DSRecordBrowserPresenterTest >> tearDown [
+
+	DSRecordBrowserPresenter resetBrowser.
+	super tearDown
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testAddFile [
+
+	| fileRef |
+	fileRef := self generateRecordsFile.
+
+	browser addFile: fileRef.
+	self assert: browser files size equals: 1.
+	self assert: self filesPresenter items size equals: 1.
+
+	self assert: self filesPresenter selectedItem equals: fileRef
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testAddFileWhenAlreadyInList [
+
+	| fileRef |
+	fileRef := self generateRecordsFile.
+
+	browser addFile: fileRef.
+	browser addFile: fileRef.
+	self assert: browser files size equals: 1.
+	self assert: self filesPresenter items size equals: 1.
+	self assert: self filesPresenter selectedItem equals: fileRef
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testAddingMultipleFiles [
+
+	| fileRef |
+	browser addFile: self generateRecordsFile.
+	fileRef := self generateRecordsFile.
+
+	browser addFile: fileRef.
+
+	self assert: browser files size equals: 2.
+	self assert: self filesPresenter items size equals: 2.
+	self assert: self filesPresenter selectedItem equals: fileRef
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testBrowserEmpty [
+
+	self assertEmpty: browser files.
+	self assert: self filesPresenter items size equals: 0.
+	self assert: self filesPresenter selectedItem equals: nil.
+	self assert: self recordsTablePresenter roots size equals: 0
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testClosingBrowser [
+
+	DSRecordBrowserPresenter toggleBrowser.
+	DSRecordBrowserPresenter toggleBrowser.
+	self deny: DSRecordBrowserPresenter uniqueInstance window isOpen
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testCreatingAndOpeningBrowser [
+
+	DSRecordBrowserPresenter toggleBrowser.
+	self assert: DSRecordBrowserPresenter uniqueInstance window isOpen.
+	DSRecordBrowserPresenter toggleBrowser
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testFilteringAClassOfRecords [
+
+	| fileRef history |
+	fileRef := self generateRecordsFile.
+	history := browser getHistoryFrom: fileRef.
+
+	browser addFile: fileRef.
+	self assert: self recordsTablePresenter roots size equals: history records size.
+
+	self recordsFilterPresenter sourceList selectItem: DSBrowseRecord.
+	self recordsFilterPresenter addSelected.
+
+	self deny: self recordsTablePresenter roots first class equals: DSBrowseRecord
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testFilteringAllRecords [
+
+	| fileRef history |
+	fileRef := self generateRecordsFile.
+	history := browser getHistoryFrom: fileRef.
+
+	browser addFile: fileRef.
+
+	self recordsFilterPresenter addAll.
+	self assert: self recordsTablePresenter roots size equals: 0
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testGetHistoryFrom [
+
+	| fileRef |
+	fileRef := self generateRecordsFile.
+	self assert: (browser getHistoryFrom: fileRef) class equals: DSRecordHistory
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testGetRecordColorAssociationsFrom [
+
+	| windows colorAssociations |
+	windows := { (DSWindowRecord new
+		            toolInfos: { (DSToolInfo new
+				             toolClassName: 'StPlaygroundPresenter';
+				             yourself) } asOrderedCollection;
+		            events: {
+				            DSWindowOpenedRecord new.
+				            DSDoItRecord new.
+				            DSStepThroughRecord new }) } asOrderedCollection.
+
+	colorAssociations := browser getRecordColorAssociationsFrom: windows.
+
+	self assert: colorAssociations first key class equals: DSWindowOpenedRecord.
+	self assert: (colorAssociations at: 2) key class equals: DSDoItRecord.
+	self assert: colorAssociations last key class equals: DSStepThroughRecord.
+
+	colorAssociations do: [ :association | self assert: association value equals: (Color fromHexString: '#70B77E') ]
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testRemoveFile [
+
+	| fileRef1 fileRef2 |
+	fileRef1 := self generateRecordsFile.
+	fileRef2 := self generateRecordsFile.
+
+	browser addFile: fileRef1.
+	browser addFile: fileRef2.
+	browser removeFile: fileRef1.
+
+	self assert: browser files size equals: 1.
+	self assert: self filesPresenter items size equals: 1.
+	self assert: self filesPresenter selectedItem equals: fileRef2
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testRemoveLastFile [
+
+	| fileRef1 |
+	fileRef1 := self generateRecordsFile.
+
+	browser addFile: fileRef1.
+	browser removeFile: fileRef1.
+
+	self assert: browser files size equals: 0.
+	self assert: self filesPresenter items size equals: 0.
+	self assert: self filesPresenter selectedItem equals: nil
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testStartRecording [
+
+	self assert: browser timerWindow isNil.
+	self deny: DSRecordRegistry autoSerialize.
+	self deny: DSSpy recordingSession.
+
+	browser startRecording.
+	self assert: DSSpy recordingSession.
+	self assert: DSRecordRegistry autoSerialize.
+	self deny: browser timerWindow isNil.
+
+	browser stopRecording
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testStopRecording [
+
+	| timerWindow |
+	browser startRecording.
+	timerWindow := browser timerWindow.
+	browser stopRecording.
+
+	self deny: (self currentWorld submorphs includes: timerWindow).
+	self assert: browser timerWindow isNil
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testUpdateRecordsTable [
+
+	| fileRef presenterMock |
+	fileRef := self generateRecordsFile.
+	presenterMock := MockObject new on: #selectedItem respond: fileRef.
+	browser updateRecordsTable: presenterMock.
+
+	self assert: self recordsTablePresenter roots first key class equals: DSBrowseRecord.
+	self assert: (self recordsTablePresenter roots at: 2) key class equals: DSMouseEnterWindowRecord.
+	self assert: (self recordsTablePresenter roots at: 3) key class equals: DSMouseLeaveWindowRecord.
+	self assert: self recordsTablePresenter roots last key class equals: DSInspectItRecord
+]
+
+{ #category : 'tests' }
+DSRecordBrowserPresenterTest >> testUpdateRecordsTableWhenAddingFile [
+
+	browser addFile: self generateRecordsFile.
+
+	self assert: self recordsTablePresenter roots first key class equals: DSBrowseRecord.
+	self assert: (self recordsTablePresenter roots at: 2) key class equals: DSMouseEnterWindowRecord.
+	self assert: (self recordsTablePresenter roots at: 3) key class equals: DSMouseLeaveWindowRecord.
+	self assert: self recordsTablePresenter roots last key class equals: DSInspectItRecord
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenterTest >> timelinePresenter [
+
+	^ browser presenterAt: #graphicTimeline 
+]
diff --git a/DebuggingSpy-Browser-Tests/DSTimerWindowTest.class.st b/DebuggingSpy-Browser-Tests/DSTimerWindowTest.class.st
new file mode 100644
index 0000000..c4a1038
--- /dev/null
+++ b/DebuggingSpy-Browser-Tests/DSTimerWindowTest.class.st
@@ -0,0 +1,54 @@
+Class {
+	#name : 'DSTimerWindowTest',
+	#superclass : 'TestCase',
+	#instVars : [
+		'timerWindow'
+	],
+	#category : 'DebuggingSpy-Browser-Tests',
+	#package : 'DebuggingSpy-Browser-Tests'
+}
+
+{ #category : 'layout' }
+DSTimerWindowTest >> currentTimeMorph [
+	"Returns the window's timeNowMorph"
+
+	^ timerWindow readSlot: (DSTimerWindow slotNamed: #currentTimeMorph)
+]
+
+{ #category : 'running' }
+DSTimerWindowTest >> setUp [
+	super setUp.
+	
+	timerWindow := DSTimerWindow new.
+]
+
+{ #category : 'tests' }
+DSTimerWindowTest >> testElapsedTime [
+
+	DSSpy recordingSession: true.
+	timerWindow startTimer.
+
+	(Delay forMilliseconds: 1000) wait.
+
+	DSSpy recordingSession: false.
+	self assert: timerWindow elapsedTime equals: 1
+]
+
+{ #category : 'tests' }
+DSTimerWindowTest >> testEmptyTimerMorph [
+
+	self assert: (Time readFrom: self timerMorph contents readStream) seconds equals: 0
+]
+
+{ #category : 'tests' }
+DSTimerWindowTest >> testTimeNowMorph [
+
+	self assert: (Time readFrom: self currentTimeMorph contents readStream) asSeconds equals: Time now asSeconds
+]
+
+{ #category : 'layout' }
+DSTimerWindowTest >> timerMorph [
+	"Returns the window's timerMorph."
+
+	^ timerWindow readSlot: (DSTimerWindow slotNamed: #timerMorph)
+]
diff --git a/DebuggingSpy-Browser-Tests/package.st b/DebuggingSpy-Browser-Tests/package.st
new file mode 100644
index 0000000..b20e695
--- /dev/null
+++ b/DebuggingSpy-Browser-Tests/package.st
@@ -0,0 +1 @@
+Package { #name : 'DebuggingSpy-Browser-Tests' }
diff --git a/DebuggingSpy-Browser/DSAbstractEventRecord.extension.st b/DebuggingSpy-Browser/DSAbstractEventRecord.extension.st
new file mode 100644
index 0000000..5696c56
--- /dev/null
+++ b/DebuggingSpy-Browser/DSAbstractEventRecord.extension.st
@@ -0,0 +1,17 @@
+Extension { #name : 'DSAbstractEventRecord' }
+
+{ #category : '*DebuggingSpy-Browser' }
+DSAbstractEventRecord class >> getLeafSubClasses [
+	"Returns a list of all non-abstract subclasses, representing all record classes."
+
+	| classes |
+	classes := OrderedCollection new.
+	self subclasses do: [ :subclass |
+			subclass subclasses isEmpty
+				ifTrue: [ classes add: subclass ]
+				ifFalse: [
+						subclass = DSDoItRecord ifTrue: [ classes add: subclass ].
+						classes addAll: subclass getLeafSubClasses ] ].
+
+	^ classes
+]
diff --git a/DebuggingSpy-Browser/DSRecordBrowserPresenter.class.st b/DebuggingSpy-Browser/DSRecordBrowserPresenter.class.st
new file mode 100644
index 0000000..5c323b1
--- /dev/null
+++ b/DebuggingSpy-Browser/DSRecordBrowserPresenter.class.st
@@ -0,0 +1,448 @@
+"
+Debugging Spy main interface which includes :
+- an opening button on the topside bar of the Pharo IDE
+- buttons to start/stop the system instrumentation
+- a window to visualize data from recording files
+"
+Class {
+	#name : 'DSRecordBrowserPresenter',
+	#superclass : 'SpPresenter',
+	#instVars : [
+		'files',
+		'recordsTablePresenter',
+		'timerWindow',
+		'graphicTimeline',
+		'recordsFilter',
+		'toolbarPresenter',
+		'fileListPresenter',
+		'startRecordButtonPresenter',
+		'stopRecordButtonPresenter'
+	],
+	#classInstVars : [
+		'uniqueInstance'
+	],
+	#category : 'DebuggingSpy-Browser',
+	#package : 'DebuggingSpy-Browser'
+}
+
+{ #category : 'world menu' }
+DSRecordBrowserPresenter class >> menuCommandOn: aBuilder [
+	"Adds the DSSpy button on topside bar."
+
+	<worldMenu>
+	(aBuilder item: #DSSpy)
+		order: 100;
+		help: 'Open the Debugging Spy browser.';
+		action: [ self toggleBrowser ]
+]
+
+{ #category : 'initialization' }
+DSRecordBrowserPresenter class >> resetBrowser [
+	"Removes the actual browser then another one will be created the next time it needs to be opened."
+
+	<script>
+	uniqueInstance := nil
+]
+
+{ #category : 'open/close' }
+DSRecordBrowserPresenter class >> toggleBrowser [
+	"Opens the browser or closes it depending on its state. If it needs to be created, then creates and opens it."
+
+	uniqueInstance ifNotNil: [
+			uniqueInstance hasWindow ifTrue: [
+					^ uniqueInstance window isOpen
+						  ifTrue: [ uniqueInstance window close ]
+						  ifFalse: [ uniqueInstance window open ] ] ].
+	self uniqueInstance open
+]
+
+{ #category : 'accessing' }
+DSRecordBrowserPresenter class >> uniqueInstance [
+	"Returns the unique browser instance and instanciates it if needed."
+
+	^ uniqueInstance ifNil: [ uniqueInstance := self new ]
+]
+
+{ #category : 'files' }
+DSRecordBrowserPresenter >> addFile: aFileReference [
+	"Adds a file in the presenter and set is as selected, which updates the records displayed."
+
+	(files includes: aFileReference)
+		ifTrue: [ ^ self inform: 'File already added !' ]
+		ifFalse: [
+				files add: aFileReference.
+				fileListPresenter items: files.
+				fileListPresenter selectItem: aFileReference ]
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> addRecordButton [
+	"Layout button which opens a window for selecting files."
+
+	^ SpToolbarButtonPresenter new
+		  label: 'Add';
+		  icon: (self iconNamed: #smallAdd);
+		  help: 'Add a new record.';
+		  action: [ self openAddFileDialog ];
+		  yourself
+]
+
+{ #category : 'initialization' }
+DSRecordBrowserPresenter >> connectPresenters [
+	"Updates the records and the timeline whenever the selected file is changed."
+
+	fileListPresenter whenSelectionChangedDo: [ :presenter |
+			fileListPresenter selectedItem ifNotNil: [
+					self updateRecordsTable: presenter.
+					self updateTimelineChart ] ].
+
+	recordsFilter whenChangedDo: [ fileListPresenter selectedItem ifNotNil: [ self updateRecordsTable: fileListPresenter ] ]
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> defaultLayout [
+
+	^ SpBoxLayout newVertical
+		  add: toolbarPresenter expand: false;
+		  add: (SpPanedLayout newHorizontal
+				   positionOfSlider: 30 percent;
+				   add: fileListPresenter;
+				   add: (SpBoxLayout newTopToBottom
+						    add: (SpTabLayout new
+								     add: recordsTablePresenter label: 'Records';
+								     add: graphicTimeline label: 'Timeline';
+								     yourself);
+						    yourself);
+				   yourself)
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> fileList [
+	"Instanciates a new presenter with a list of added files."
+
+	^ self newList
+		  items: self files;
+		  display: [ :file | file basenameWithoutExtension ];
+		  actions: self listAddedFilesActions;
+		  yourself
+]
+
+{ #category : 'accessing' }
+DSRecordBrowserPresenter >> files [
+
+	^ files ifNil: [ files := OrderedCollection new ]
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> filterRecordsButton [
+	"Instanciates a new layout button which opens the records' filter window."
+
+	^ SpToolbarButtonPresenter new
+		  label: 'Filter';
+		  icon: (self iconNamed: #diff);
+		  help: 'Filter records.';
+		  action: [ recordsFilter open ];
+		  yourself
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenter >> getHistoryFrom: aFileReference [
+	"Returns the generated history using the specified file reference which should countains DSSpy records."
+
+	^ DSRecordHistory on: (DSSpy materialize: aFileReference)
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenter >> getRecordColorAssociationsFrom: aWindowRecordCollection [
+	"Returns a sorted collection associating each record with its window's corresponding color, sorted by record's dateTime."
+
+	| recordColorsAssociations |
+	recordColorsAssociations := OrderedCollection new.
+
+	aWindowRecordCollection do: [ :windowRecord |
+		recordColorsAssociations addAll: (windowRecord events collect: [ :record | record -> (self getWindowColorFrom: windowRecord) ]) ].
+
+	^ recordColorsAssociations sorted: [ :recordA :recordB | recordA key dateTime < recordB key dateTime ]
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserPresenter >> getTimelinePointsFrom: aHistory [
+	"Returns a list of plots for the timeline chart."
+
+	^ aHistory windows collectWithIndex: [ :w :index |
+			  RSTimeLinePlot new
+				  entries: {
+						  w events first dateTime asNanoSeconds.
+						  w events last dateTime asNanoSeconds }
+				  at: index;
+				  color: (self getWindowColorFrom: w) ]
+]
+
+{ #category : 'color' }
+DSRecordBrowserPresenter >> getWindowColorFrom: aWindowRecord [
+	"Returns the window associated color, and the default color otherwise."
+
+	aWindowRecord isBrowser ifTrue: [ ^ Color fromHexString: '#2A2AB7' ].
+	aWindowRecord isInspector ifTrue: [ ^ Color fromHexString: '#FFC300' ].
+	aWindowRecord isDebugger ifTrue: [ ^ Color fromHexString: '#C41E3D' ].
+
+	aWindowRecord isPlayground ifTrue: [ ^ Color fromHexString: '#70B77E' ].
+	aWindowRecord isBreakpointBrowser ifTrue: [ ^ Color fromHexString: '#7C238C' ].
+	aWindowRecord isCritiqueBrowser ifTrue: [ ^ Color fromHexString: '#A45C15' ].
+	aWindowRecord isEpicea ifTrue: [ ^ Color fromHexString: '#345e54' ].
+	aWindowRecord isIceberg ifTrue: [ ^ Color fromHexString: '#2B5BA9' ].
+	aWindowRecord isRewriter ifTrue: [ ^ Color fromHexString: '#292929' ].
+
+	^ Color gray
+]
+
+{ #category : 'initialization' }
+DSRecordBrowserPresenter >> initializePresenters [
+
+	startRecordButtonPresenter := self startRecordButton.
+	stopRecordButtonPresenter := self stopRecordButton.
+	toolbarPresenter := self toolbar.
+	fileListPresenter := self fileList.
+	recordsTablePresenter := self recordsTable.
+	graphicTimeline := self newRoassal.
+	recordsFilter := self recordsFilter
+]
+
+{ #category : 'operations' }
+DSRecordBrowserPresenter >> listAddedFilesActions [
+	"Returns a list of actions for the list of added files. Action are: inspecting raw records, inspecting history, or removing the selected file from the list."
+
+	^ SpActionGroup new
+		  addActionWith: [ :anItem |
+				  anItem
+					  name: 'Inspect';
+					  iconName: #inspect;
+					  description: 'Inspect the raw records';
+					  shortcutKey: $i meta;
+					  action: [ (DSSpy materialize: fileListPresenter selectedItem) inspect ] ];
+		  addActionWith: [ :anItem |
+				  anItem
+					  name: 'Inspect history';
+					  iconName: #history;
+					  description: 'Inspect the record history';
+					  shortcutKey: $h meta;
+					  action: [ (self getHistoryFrom: fileListPresenter selectedItem) inspect ] ];
+		  addActionWith: [ :anItem |
+				  anItem
+					  name: 'Remove';
+					  iconName: #remove;
+					  description: 'Remove the record from list';
+					  shortcutKey: $x meta;
+					  action: [ self removeFile: fileListPresenter selectedItem ] ];
+		  yourself
+]
+
+{ #category : 'operations' }
+DSRecordBrowserPresenter >> openAddFileDialog [
+	"Opens a dialog where the user can select a file to add in the browser."
+
+	| newFiles |
+	newFiles := StOpenFilePresenter new
+		            beMultipleSelection;
+		            defaultFolder: DSSpy logger loggingDirectory;
+		            openModal.
+	newFiles ifNotNil: [ newFiles do: [ :file | self addFile: file asFileReference ] ]
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> recordsFilter [
+	"Instanciates a new chooser that displays every record classes that could be used to filter records in table."
+
+	^ SpChooserPresenter new sourceItems: DSAbstractEventRecord getLeafSubClasses
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> recordsTable [
+	"Instanciates a new records table that displays data based on the selected file's records."
+
+	^ self newTreeTable
+		  addColumn: (SpStringTableColumn new
+				   title: 'Event';
+				   displayBackgroundColor: [ :association | association value ];
+				   evaluated: [ :association | association key eventName asString ];
+				   displayColor: [ :aRecord | Color white ];
+				   yourself);
+		  addColumn: (SpStringTableColumn new
+				   title: 'Event type';
+				   displayBackgroundColor: [ :association | association value ];
+				   evaluated: [ :association | association key class asString ];
+				   displayColor: [ :aRecord | Color white ];
+				   yourself);
+		  addColumn: (SpStringTableColumn new
+				   title: 'Time';
+				   displayBackgroundColor: [ :association | association value ];
+				   evaluated: [ :association | association key dateTime asTime print24 ];
+				   displayColor: [ :aRecord | Color white ];
+				   yourself);
+		  beResizable;
+		  actions: self recordsTableActions;
+		  yourself
+]
+
+{ #category : 'operations' }
+DSRecordBrowserPresenter >> recordsTableActions [
+	"Return a list of actions which can be done on a record from the table. For example, inspect the selected record."
+
+	^ SpActionGroup new
+		  addActionWith: [ :anItem |
+				  anItem
+					  name: 'Inspect';
+					  iconName: #inspect;
+					  description: 'Inspect the raw records';
+					  shortcutKey: $i meta;
+					  action: [ recordsTablePresenter selectedItem key inspect ] ];
+		  yourself
+]
+
+{ #category : 'files' }
+DSRecordBrowserPresenter >> removeFile: aFileReference [
+	"Removes the selected file from the list and updates the selected item depending on the list number of elements."
+
+	files := files reject: [ :fileReference | fileReference = aFileReference ].
+	fileListPresenter items: self files.
+	fileListPresenter selectItem: (files ifNotEmpty: [ files last ])
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> startRecordButton [
+	"Instanciates a button that starts the DSSpy recording session on click."
+
+	^ SpToolbarButtonPresenter new
+		  label: 'Start';
+		  icon: (self iconNamed: #glamorousGo);
+		  help: 'Start recording events.';
+		  action: [ self startRecording ];
+		  enabled: DSSpy recordingSession not;
+		  yourself
+]
+
+{ #category : 'recording' }
+DSRecordBrowserPresenter >> startRecording [
+	"Starts recording events and instianciates a timerWindow which displays a timer and shows that Debugging Spy is recordering."
+
+	timerWindow := DSTimerWindow new.
+	timerWindow openInWorld.
+	DSSpyInstrumenter instrumentSystem.
+	timerWindow startTimer.
+	self updateToolbar
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> stopRecordButton [
+	"Instanciates a button that stops the DSSpy recording session on click."
+
+	^ SpToolbarButtonPresenter new
+		  label: 'Stop';
+		  icon: (self iconNamed: #stop);
+		  help: 'Stop recording events.';
+		  action: [ self stopRecording ];
+		  enabled: DSSpy recordingSession;
+		  yourself
+]
+
+{ #category : 'recording' }
+DSRecordBrowserPresenter >> stopRecording [
+	"Stops the recording session and closes the timer window."
+
+	DSSpyInstrumenter stopInstrumentation.
+	self currentWorld removeMorph: timerWindow.
+	self updateToolbar.
+	timerWindow := nil
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> timelineChart [
+	"Returns a chart that represents a timeline using the file list presenter's data for its plots."
+
+	| history names chart data |
+	fileListPresenter selectedItem ifNil: [ ^ nil ].
+
+	history := self getHistoryFrom: fileListPresenter selectedItem.
+	names := history windows collect: [ :i | i getWindowType ].
+
+	data := self getTimelinePointsFrom: history.
+	data size < 2 ifTrue: [ ^ nil ].
+
+	chart := RSCompositeChart new.
+	chart addAll: data.
+
+	chart verticalTick fromNames: names.
+
+	chart horizontalTick
+		useNiceLabel;
+		numberOfTicks: history windows size // 2;
+		useDiagonalLabel;
+		labelConversion: [ :v | (DateAndTime fromSeconds: v // 1000000000) asTime ]. "Plots are instancied using their dateTime as nano seconds to prevent events which last less than a second to be hided, so we convert them into seconds to get the label."
+
+	chart build.
+	^ chart
+]
+
+{ #category : 'accessing' }
+DSRecordBrowserPresenter >> timerWindow [
+
+	^ timerWindow
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> toolbar [
+	"Instanciates a new toolbar to be displayed on layout."
+
+	^ self newToolbar
+		  addItem: self addRecordButton;
+		  addItem: startRecordButtonPresenter;
+		  addItem: stopRecordButtonPresenter;
+		  addItem: self filterRecordsButton
+]
+
+{ #category : 'operations' }
+DSRecordBrowserPresenter >> updateRecordsTable: filesPresenter [
+	"Updates the records' table presenter and add to each record its corresponding color."
+
+	| fileRef recordColorAssociations |
+	recordColorAssociations := Array new.
+	fileRef := filesPresenter selectedItem.
+
+	fileRef ifNotNil: [
+			recordColorAssociations := self getRecordColorAssociationsFrom: (self getHistoryFrom: fileRef) windows.
+			recordColorAssociations := recordColorAssociations reject: [ :association |
+				                           recordsFilter chosenItems includes: association key class ] ].
+
+	recordsTablePresenter roots: recordColorAssociations 
+]
+
+{ #category : 'operations' }
+DSRecordBrowserPresenter >> updateTimelineChart [
+	"Regenerates the timeline chart using the selected record's data"
+
+	| chart |
+	chart := self timelineChart.
+	chart
+		ifNil: [ graphicTimeline script: [ :canvas |  ] ]
+		ifNotNil: [ graphicTimeline script: [ :canvas | chart renderIn: canvas ] ].
+	graphicTimeline refresh
+]
+
+{ #category : 'layout' }
+DSRecordBrowserPresenter >> updateToolbar [
+
+	startRecordButtonPresenter enabled: DSSpy recordingSession not.
+	stopRecordButtonPresenter enabled: DSSpy recordingSession
+]
+
+{ #category : 'accessing' }
+DSRecordBrowserPresenter >> windowIcon [
+
+	^ self iconNamed: #smallObjects 
+]
+
+{ #category : 'accessing' }
+DSRecordBrowserPresenter >> windowTitle [
+
+	^ 'Debugging record browser'
+]
diff --git a/DebuggingSpy-Browser/DSTimerWindow.class.st b/DebuggingSpy-Browser/DSTimerWindow.class.st
new file mode 100644
index 0000000..19f5e63
--- /dev/null
+++ b/DebuggingSpy-Browser/DSTimerWindow.class.st
@@ -0,0 +1,151 @@
+"
+I am a window displaying timer while DebuggingSpy is recording.
+"
+Class {
+	#name : 'DSTimerWindow',
+	#superclass : 'SystemWindow',
+	#instVars : [
+		'timerMorph',
+		'startTime',
+		'currentTimeMorph'
+	],
+	#category : 'DebuggingSpy-Browser',
+	#package : 'DebuggingSpy-Browser'
+}
+
+{ #category : 'initialization' }
+DSTimerWindow >> buildUI [
+	"Builds the windows UI, it contains : an icon which shows that Debugging Spy is recording, a chronometer, a timer with current time and a stop recording button."
+
+	timerMorph := self timerMorph.
+	currentTimeMorph := self currentTimeMorph.
+
+	self
+		addMorph: self recordingIcon;
+		addMorph: timerMorph;
+		addMorph: currentTimeMorph;
+		addMorph: self stopButton
+]
+
+{ #category : 'resize/collapse' }
+DSTimerWindow >> collapseOrExpand [
+
+	^ self
+]
+
+{ #category : 'layout' }
+DSTimerWindow >> currentTimeMorph [
+	"Instanciates a new morph that shows the actual time."
+
+	^ StringMorph new
+		  contents: Time now print24;
+		  position: 75 @ 6
+]
+
+{ #category : 'timer' }
+DSTimerWindow >> elapsedTime [
+	"Returns the elapsed time since the timer's start."
+
+	startTime ifNil: [ ^ 0 ].
+	^ Time current asSeconds - startTime
+]
+
+{ #category : 'initialization' }
+DSTimerWindow >> initialize [
+
+	super initialize.
+	self minimumExtent: self size.
+	self initializeProperties.
+	self buildUI.
+	self initializeTimers
+]
+
+{ #category : 'initialization' }
+DSTimerWindow >> initializeProperties [
+
+	self
+		setLabel: 'DSSpy timer';
+		extent: self size;
+		beSticky;
+		makeUnclosable;
+		removeLabelArea;
+		removeBoxes;
+		beUnresizeable
+]
+
+{ #category : 'initialization' }
+DSTimerWindow >> initializeTimers [
+	"Creates a new process that displays the current time even if the timer is not started. The timer would be updated whenever the record session starts."
+
+	[
+		[ true ] whileTrue: [
+				DSSpy recordingSession ifTrue: [ timerMorph contents: (Time fromSeconds: self elapsedTime) print24 ].
+				currentTimeMorph contents: Time now print24.
+				(Delay forMilliseconds: 50) wait ] ] fork
+]
+
+{ #category : 'accessing' }
+DSTimerWindow >> margin [
+	"Space around the window"
+
+	^ 5 @ 32
+]
+
+{ #category : 'wiw support' }
+DSTimerWindow >> morphicLayerNumber [
+	"To ensure the recorder window is always displayed at screen and cannot be covered"
+
+	^ 12
+]
+
+{ #category : 'opening' }
+DSTimerWindow >> openInWorld [
+
+	super openInWorld.
+	self position: self currentWorld extent - self extent - self margin
+]
+
+{ #category : 'layout' }
+DSTimerWindow >> recordingIcon [
+	"Instanciates a new icon that shows that Debugging Spy is recording."
+
+	^ ImageMorph new
+		  image: (self iconNamed: #glamorousRedCircle);
+		  position: 0 @ 7;
+		  yourself
+]
+
+{ #category : 'accessing' }
+DSTimerWindow >> size [
+
+	^ 150 @ 30
+]
+
+{ #category : 'timer' }
+DSTimerWindow >> startTimer [
+	"Starts a new process for the timer."
+
+	DSSpy recordingSession ifFalse: [ ^ self ].
+	startTime := Time current asSeconds
+]
+
+{ #category : 'layout' }
+DSTimerWindow >> stopButton [
+	"Instanciates a new morph button that stops the recording and closes the window when clicked."
+
+	^ PluggableButtonMorph new
+		  label: (IconicListItemMorph new icon: (self iconNamed: #stop));
+		  model: DSRecordBrowserPresenter uniqueInstance;
+		  actionSelector: #stopRecording;
+		  position: 125 @ 4;
+		  yourself
+]
+
+{ #category : 'layout' }
+DSTimerWindow >> timerMorph [
+	"Insanciates a new morph that contains the seconds timer on the window."
+
+	^ StringMorph new
+		  contents: '00:00:000';
+		  position: 15 @ 6
+]
diff --git a/DebuggingSpy-Browser/package.st b/DebuggingSpy-Browser/package.st
new file mode 100644
index 0000000..0831d90
--- /dev/null
+++ b/DebuggingSpy-Browser/package.st
@@ -0,0 +1 @@
+Package { #name : 'DebuggingSpy-Browser' }
diff --git a/DebuggingSpy-Tests/DSRecordTest.class.st b/DebuggingSpy-Tests/DSRecordTest.class.st
index 7b8743d..0a3b4b9 100644
--- a/DebuggingSpy-Tests/DSRecordTest.class.st
+++ b/DebuggingSpy-Tests/DSRecordTest.class.st
@@ -9,6 +9,26 @@ Class {
 	#tag : 'Tests - model'
 }
 
+{ #category : 'tests' }
+DSRecordTest >> testGettingLeafSubclasses [
+
+	| subclasses |
+	subclasses := OrderedCollection new
+		              add: DSDebugPointAdd;
+		              add: DSDebugPointChanged;
+		              add: DSDebugPointHit;
+		              add: DSDebugPointRemoved;
+		              yourself.
+
+	self assert: DSAbstractExtendedRecord getLeafSubClasses equals: subclasses
+]
+
+{ #category : 'tests' }
+DSRecordTest >> testGettingLeafSubclassesIncludesDSDoItRecord [
+
+	self assert: (DSAbstractEventRecord getLeafSubClasses includes: DSDoItRecord)
+]
+
 { #category : 'tests' }
 DSRecordTest >> testRecordPrinting [
 
diff --git a/DebuggingSpy/DSSTONFileLogger.class.st b/DebuggingSpy/DSSTONFileLogger.class.st
index 4b780d7..c43d04a 100644
--- a/DebuggingSpy/DSSTONFileLogger.class.st
+++ b/DebuggingSpy/DSSTONFileLogger.class.st
@@ -80,6 +80,12 @@ DSSTONFileLogger >> loggingFileName [
 		  loggingFilename := self defaultLoggingFileName ]
 ]
 
+{ #category : 'accessing' }
+DSSTONFileLogger >> loggingFileName: aFileName [
+
+	loggingFilename := aFileName
+]
+
 { #category : 'accessing' }
 DSSTONFileLogger >> loggingFileReference [
 
@@ -87,6 +93,12 @@ DSSTONFileLogger >> loggingFileReference [
 		  loggingFileReference := self ensureCreateLoggingFileReference ]
 ]
 
+{ #category : 'accessing' }
+DSSTONFileLogger >> loggingFileReference: aFileReference [
+
+	^ loggingFileReference := aFileReference
+]
+
 { #category : 'initialization' }
 DSSTONFileLogger >> reset [
 
diff --git a/DebuggingSpy/DSSpyInstrumenter.class.st b/DebuggingSpy/DSSpyInstrumenter.class.st
index 14407d3..f2879db 100644
--- a/DebuggingSpy/DSSpyInstrumenter.class.st
+++ b/DebuggingSpy/DSSpyInstrumenter.class.st
@@ -23,6 +23,9 @@ DSSpyInstrumenter class >> stopInstrumentation [
 
 	"Stop the recording session"
 	DSSpy recordingSession: false.
+	
+	"Stop the auto serialization"
+	DSRecordRegistry autoSerialize: false.
 
 	"Stop listening to events for recording"
 	SystemAnnouncer uniqueInstance unsubscribe: DSSpy.
diff --git a/DebuggingSpy/DSWindowRecord.class.st b/DebuggingSpy/DSWindowRecord.class.st
index a722898..8e50f9c 100644
--- a/DebuggingSpy/DSWindowRecord.class.st
+++ b/DebuggingSpy/DSWindowRecord.class.st
@@ -103,6 +103,14 @@ DSWindowRecord >> events: anObject [
 	events := anObject
 ]
 
+{ #category : 'accessing' }
+DSWindowRecord >> getWindowType [
+
+	toolInfos ifNotNil: [ toolInfos ifNotEmpty: [ ^ toolInfos first toolClassName ] ].
+	type isString ifTrue: [ ^ type ].
+	^ 'External Window'
+]
+
 { #category : 'accessing' }
 DSWindowRecord >> idleTime [
 
@@ -213,13 +221,7 @@ DSWindowRecord >> printOn: ws [
 { #category : 'printing' }
 DSWindowRecord >> printTypeOn: aStream [
 
-	toolInfos ifNotNil: [
-		aStream << toolInfos first toolClassName.
-		^ self ].
-	type isString ifTrue: [
-		aStream << type.
-		^ self ].
-	aStream << 'External Window'
+	aStream << self getWindowType
 ]
 
 { #category : 'accessing' }