diff --git a/.forceignore b/.forceignore
index eeed72a8..bffd4f14 100644
--- a/.forceignore
+++ b/.forceignore
@@ -2,4 +2,7 @@
 **/*.ts
 **/tsconfig*.json
 **/*.tsbuildinfo
-**/eslint.config.mjs
\ No newline at end of file
+**/eslint.config.mjs
+**/jsconfig.json
+
+**/.eslintrc.json
diff --git a/.gitignore b/.gitignore
index 9de1c41a..23990ae2 100644
--- a/.gitignore
+++ b/.gitignore
@@ -38,4 +38,6 @@ target/
 node_modules/
 /.illuminatedCloud/
 **/tsconfig*.json
-**/*.tsbuildinfo
\ No newline at end of file
+**/*.tsbuildinfo
+package-lock.json
+package.json
diff --git a/force-app/main/default/classes/SummitEventsLinkHandler.cls b/force-app/main/default/classes/SummitEventsLinkHandler.cls
new file mode 100644
index 00000000..b1c63cd1
--- /dev/null
+++ b/force-app/main/default/classes/SummitEventsLinkHandler.cls
@@ -0,0 +1,8 @@
+public with sharing class SummitEventsLinkHandler {
+    public static void run(Map<Id,Summit_Events__c> newMap) {
+        new SummitEventsRtfLinkPipeline(newMap).run();
+    }
+
+    // Future consideration: add async logic here
+
+}
\ No newline at end of file
diff --git a/force-app/main/default/classes/SummitEventsLinkHandler.cls-meta.xml b/force-app/main/default/classes/SummitEventsLinkHandler.cls-meta.xml
new file mode 100644
index 00000000..82775b98
--- /dev/null
+++ b/force-app/main/default/classes/SummitEventsLinkHandler.cls-meta.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<ApexClass xmlns="http://soap.sforce.com/2006/04/metadata">
+    <apiVersion>65.0</apiVersion>
+    <status>Active</status>
+</ApexClass>
diff --git a/force-app/main/default/classes/SummitEventsRtfLinkPipeline.cls b/force-app/main/default/classes/SummitEventsRtfLinkPipeline.cls
new file mode 100644
index 00000000..3394e84d
--- /dev/null
+++ b/force-app/main/default/classes/SummitEventsRtfLinkPipeline.cls
@@ -0,0 +1,283 @@
+public without sharing class SummitEventsRtfLinkPipeline {
+    
+    // Inelegant, but schema introspection can't differentiate RTF from regular text fields
+    private static final Set<String> RICHTEXT_FIELDS = new Set<String>{
+        'Event_Full_Text__c', 'Event_Confirmation_Description__c',
+        'Event_Additional_Questions_Description__c', 
+        'Event_Appointment_Description__c', 'Event_Footer__c', 
+        'Event_Submit_Description__c', 'Event_Cancel_Review_Description__c',
+        'Event_Payment_Due_Description__c', 'Event_Payment_Received_Description__c',
+        'Event_description__c', 'Donation_Description__c', 
+        'Guest_Registration_Description__c'
+    };
+
+    private static final String namespace = SummitEventsNamespace.StrTokenNSPrefix('');
+    
+    private Map<Id,ContentDistribution> cvIdToCDMap;
+    private List<SummitEventWrapper> wrappedEventList;
+    private List<Id> idList;
+    private String executionStage;
+    
+    public SummitEventsRtfLinkPipeline(Map<Id,Summit_Events__c> newMap) {
+        this.cvIdToCDMap = new Map<Id,ContentDistribution>();
+        this.wrappedEventList = new List<SummitEventWrapper>();
+        this.idList = new List<Id>(newMap.keySet());
+    }
+
+    public void run() {
+        this.executionStage = 'run';
+        try {
+            filter();
+            scan();
+            prepare();
+            create();
+            push();
+        } catch(Exception e) {
+            System.debug('Pipeline failed at stage ' + this.executionStage + ': ' + e.getMessage());
+        }
+    }
+
+    /**
+     * Cheap first-pass filter to select and wrap Summit_Events__c records
+     * that have RTF fields with links to ContentVersion records.
+     */
+    @TestVisible
+    private void filter() {
+
+        this.executionStage = 'filter';
+
+        List<Summit_Events__c> freshEventList = new List<Summit_Events__c>();
+        List<String> fields = new List<String>();
+        String query = '';
+
+        Summit_Events__c schemaObject = new Summit_Events__c();
+        Map<String,SObjectField> fieldMap = 
+            schemaObject
+                .getSObjectType()
+                .getDescribe()
+                .fields
+                .getMap();
+
+        for(String field : RICHTEXT_FIELDS) {
+
+            Boolean isUpdateable = fieldMap.get(namespace + field).getDescribe().isUpdateable();
+            
+            if(isUpdateable) {
+                fields.add(namespace + field);
+            }
+        }
+	    
+        if(fields.isEmpty()) {
+            throw new SummitEventsException('No RTF fields found or user lacks sufficient permissions to update fields');
+        }
+
+        String fieldList = String.join(fields, ', ');
+        query = 'SELECT Name, ' + fieldList + ' FROM ' + namespace + 'Summit_Events__c WHERE Id IN :idList';
+        freshEventList = Database.query(query);
+
+        for(Summit_Events__c freshEvent : freshEventList) {
+            SummitEventWrapper wrappedEvent = new SummitEventWrapper();
+            for (String field : fields) {
+                String fieldVal = (String) freshEvent?.get(field);
+                if(!String.isBlank(fieldVal) && fieldVal.contains('<img src=') && fieldVal.contains('versionId=068')) {
+                    wrappedEvent.fieldsWithLinks.add(field);
+                }
+            }
+            if(!wrappedEvent.fieldsWithLinks.isEmpty()) {
+                wrappedEvent.event = freshEvent;
+                this.wrappedEventList.add(wrappedEvent);
+            }
+        } 
+    }
+
+    /**
+     * Scan through wrapped events and find all the ContentVersion Ids.
+     * Pattern and Matcher would have less cognitive overhead, but they
+     * come attached to significant time complexity, so we're going to
+     * roll our own manual string ops. Even without direct access to char
+     * arrays, this should still be O(n). 
+     */
+    @TestVisible
+    private void scan() {
+        
+        this.executionStage = 'scan';
+
+        for (SummitEventWrapper wrappedEvent : wrappedEventList) {
+            Map<String, List<SummitFieldItem>> tempMap = new Map<String, List<SummitFieldItem>>();
+        
+            for (String field : wrappedEvent.fieldsWithLinks) {
+                String html = (String) wrappedEvent.event.get(field);
+                List<SummitFieldItem> items = new List<SummitFieldItem>();
+            
+                Integer pos = 0;
+                while (true) {
+                    // Find the next <img src="...">
+                    Integer tagStart = html.indexOf('<img', pos);
+                    if (tagStart == -1) 
+                        break;
+                
+                    Integer srcStart = html.indexOf('src="', tagStart);
+                    if (srcStart == -1) 
+                        break;
+                
+                    srcStart += 5; // past src="
+                    Integer srcEnd = html.indexOf('"', srcStart);
+                    if (srcEnd == -1) 
+                        break;
+                
+                    String url = html.substring(srcStart, srcEnd);
+                    pos = srcEnd + 1;
+                
+                    // Look for versionId
+                    Integer idIdx = url.indexOf('versionId=068');
+                    if (idIdx == -1) 
+                        continue;
+                
+                    Integer idStart = idIdx + 'versionId='.length();
+                    Integer i = idStart;
+                    String alphaNumerics = 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789';
+                    while (i < url.length() && alphaNumerics.indexOf(url.substring(i, i + 1)) != -1)
+                        i++;
+                
+                    String possibleId = url.substring(idStart, i);
+                    if (possibleId.startsWith('068')) {
+                        SummitFieldItem sfi = new SummitFieldItem();
+                        sfi.cvId = (Id) possibleId;
+                        sfi.url = url;
+                        items.add(sfi);
+                    }
+                }
+            
+                if (!items.isEmpty()) {
+                    tempMap.put(field, items);
+                }
+            }
+            wrappedEvent.fieldsToLinkMap = tempMap;
+        }
+    }
+    
+    /**
+     * Prepare the pipeline for execution; populate some final values
+     * we'll need for execution.
+     */
+    @TestVisible
+    private void prepare() {
+
+        this.executionStage = 'prepare';
+
+        Set<Id> cvIdSet = new Set<Id>();
+        for(SummitEventWrapper wrappedEvent : wrappedEventList) {
+            for(String field : wrappedEvent.fieldsToLinkMap.keySet()) {
+                for(SummitFieldItem sfi : wrappedEvent.fieldsToLinkMap.get(field)) {
+                    cvIdSet.add(sfi.cvId);
+                }
+            }
+        }
+
+        List<ContentDistribution> cdList = [
+            SELECT Id,
+                   DistributionPublicUrl,
+                   Name,
+                   ContentVersionId
+            FROM   ContentDistribution
+            WHERE  ContentVersionId IN :cvIdSet
+        ];
+
+        for(ContentDistribution cd : cdList) {
+            this.cvIdToCDMap.put(cd.ContentVersionId, cd);
+        }
+    }
+
+    /**
+     * Create ContentDistribution records for any ContentVersion records
+     * that are not already linked to a ContentDistribution record.
+     */
+    @TestVisible
+    private void create() {
+
+        this.executionStage = 'create';
+
+        List<ContentDistribution> cdInsertList = new List<ContentDistribution>();
+        Set<Id> visited = new Set<Id>();
+        
+        for(SummitEventWrapper wrappedEvent : wrappedEventList) {
+            for(String field : wrappedEvent.fieldsToLinkMap.keySet()) {
+                Integer i = 0;
+                for(SummitFieldItem sfi : wrappedEvent.fieldsToLinkMap.get(field)) {
+                    if(!cvIdToCDMap.containsKey(sfi.cvId) && !visited.contains(sfi.cvId)) {
+                        ContentDistribution cd = new ContentDistribution();
+                        cd.ContentVersionId = sfi.cvId;
+                        cd.Name = wrappedEvent.event.Name + ' - ' + field + i++;
+                        cdInsertList.add(cd);
+                        visited.add(sfi.cvId);
+                    }
+                }
+            }
+        }
+
+        if(!cdInsertList.isEmpty()) {
+            insert cdInsertList;
+
+            List<ContentDistribution> refreshed = [
+                SELECT Id, 
+                       DistributionPublicUrl,
+                       Name, 
+                       ContentVersionId  
+                FROM   ContentDistribution 
+                WHERE  Id IN :cdInsertList
+            ];
+
+            for(ContentDistribution cd : refreshed) {
+                cvIdToCDMap.put(cd.ContentVersionId, cd);
+            }
+        }
+    }
+
+    /**
+     * Replace all URLs in the RTF fields with the corresponding ContentDistribution
+     * record's DistributionPublicUrl, and update the Summit_Events__c record.
+     */
+    @TestVisible
+    private void push() { 
+
+        this.executionStage = 'push';
+
+        List<Summit_Events__c> updateList = new List<Summit_Events__c>();
+
+        for(SummitEventWrapper wrappedEvent : wrappedEventList) {
+            Summit_Events__c tempEvent = new Summit_Events__c();
+            tempEvent.Id = wrappedEvent.event.Id; // trigger records are immutable, we must create new records
+            for(String field : wrappedEvent.fieldsWithLinks) {
+                String rtf = (String) wrappedEvent.event.get(field);
+                for(SummitFieldItem sfi : wrappedEvent.fieldsToLinkMap.get(field)) {
+                    rtf = rtf.replace(sfi.url, cvIdToCDMap.get(sfi.cvId).DistributionPublicUrl);
+                }
+                tempEvent.put(field,rtf);
+            }
+            updateList.add(tempEvent);
+        }
+
+        if(!updateList.isEmpty()) {
+            this.executionStage = 'push.DML';
+            update updateList;
+        }
+     }
+
+    // Simple wrapper to aggregate relevant values we'll use
+    private class SummitEventWrapper {
+        Summit_Events__c event;
+        Set<String> fieldsWithLinks;
+        Map<String,List<SummitFieldItem>> fieldsToLinkMap;
+
+        private SummitEventWrapper() { 
+            this.fieldsWithLinks = new Set<String>(); 
+            this.fieldsToLinkMap = new Map<String,List<SummitFieldItem>>();
+        }
+    }
+
+    private class SummitFieldItem {
+        String url;
+        Id cvId;
+        private SummitFieldItem() {}
+    }
+}
\ No newline at end of file
diff --git a/force-app/main/default/classes/SummitEventsRtfLinkPipeline.cls-meta.xml b/force-app/main/default/classes/SummitEventsRtfLinkPipeline.cls-meta.xml
new file mode 100644
index 00000000..82775b98
--- /dev/null
+++ b/force-app/main/default/classes/SummitEventsRtfLinkPipeline.cls-meta.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<ApexClass xmlns="http://soap.sforce.com/2006/04/metadata">
+    <apiVersion>65.0</apiVersion>
+    <status>Active</status>
+</ApexClass>
diff --git a/force-app/main/default/objects/Summit_Events_Settings__c/fields/Opt_Into_Link_Automation__c.field-meta.xml b/force-app/main/default/objects/Summit_Events_Settings__c/fields/Opt_Into_Link_Automation__c.field-meta.xml
new file mode 100644
index 00000000..d3165e8b
--- /dev/null
+++ b/force-app/main/default/objects/Summit_Events_Settings__c/fields/Opt_Into_Link_Automation__c.field-meta.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<CustomField xmlns="http://soap.sforce.com/2006/04/metadata">
+    <fullName>Opt_Into_Link_Automation__c</fullName>
+    <defaultValue>false</defaultValue>
+    <description>Opt into automatic creation of public links backed by ContentVersion files found in Summit Events RTFs.</description>
+    <externalId>false</externalId>
+    <inlineHelpText>Opt into automatic creation of public links backed by ContentVersion files found in Summit Events RTFs.</inlineHelpText>
+    <label>Opt into link automation</label>
+    <trackTrending>false</trackTrending>
+    <type>Checkbox</type>
+</CustomField>
diff --git a/force-app/main/default/objects/Summit_Events_Settings__c/fields/Turn_off_Summit_Events_Trigger__c.field-meta.xml b/force-app/main/default/objects/Summit_Events_Settings__c/fields/Turn_off_Summit_Events_Trigger__c.field-meta.xml
new file mode 100644
index 00000000..da9e5c72
--- /dev/null
+++ b/force-app/main/default/objects/Summit_Events_Settings__c/fields/Turn_off_Summit_Events_Trigger__c.field-meta.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<CustomField xmlns="http://soap.sforce.com/2006/04/metadata">
+    <fullName>Turn_off_Summit_Events_Trigger__c</fullName>
+    <defaultValue>false</defaultValue>
+    <description>Turns off Summit Event App's Summit Events trigger.</description>
+    <externalId>false</externalId>
+    <inlineHelpText>Turns off Summit Event App's Summit Events trigger.</inlineHelpText>
+    <label>Turn off Summit Events Trigger</label>
+    <trackTrending>false</trackTrending>
+    <type>Checkbox</type>
+</CustomField>
diff --git a/force-app/main/default/triggers/SummitEventsSummitEventTrigger.trigger b/force-app/main/default/triggers/SummitEventsSummitEventTrigger.trigger
new file mode 100644
index 00000000..907fa3e1
--- /dev/null
+++ b/force-app/main/default/triggers/SummitEventsSummitEventTrigger.trigger
@@ -0,0 +1,13 @@
+trigger SummitEventsSummitEventTrigger on Summit_Events__c (before insert, before update, after insert, after update) {
+    Summit_Events_Settings__c SummitEventsSettings = Summit_Events_Settings__c.getOrgDefaults();
+    if (!SummitEventsSettings.Turn_off_Summit_Events_Trigger__c) {
+        if (SummitEventsSettings.Opt_Into_Link_Automation__c) {
+            if (Trigger.isInsert && Trigger.isAfter) {
+                SummitEventsLinkHandler.run(Trigger.newMap);
+            }
+            if (Trigger.isUpdate && Trigger.isAfter) {
+                SummitEventsLinkHandler.run(Trigger.newMap);
+            }
+        }
+    }
+}
\ No newline at end of file
diff --git a/force-app/main/default/triggers/SummitEventsSummitEventTrigger.trigger-meta.xml b/force-app/main/default/triggers/SummitEventsSummitEventTrigger.trigger-meta.xml
new file mode 100644
index 00000000..260ec509
--- /dev/null
+++ b/force-app/main/default/triggers/SummitEventsSummitEventTrigger.trigger-meta.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<ApexTrigger xmlns="http://soap.sforce.com/2006/04/metadata">
+  <apiVersion>64.0</apiVersion>
+  <status>Active</status>
+</ApexTrigger>
diff --git a/force-app/test/default/classes/SummitEventsRtfLinkPipeline_TEST.cls b/force-app/test/default/classes/SummitEventsRtfLinkPipeline_TEST.cls
new file mode 100644
index 00000000..edfe34bb
--- /dev/null
+++ b/force-app/test/default/classes/SummitEventsRtfLinkPipeline_TEST.cls
@@ -0,0 +1,48 @@
+@IsTest
+public with sharing class SummitEventsRtfLinkPipeline_TEST {
+
+    @TestSetup
+    static void makeData() {
+        ContentVersion cv = new ContentVersion(
+            Title = 'Test',
+            PathOnClient = 'test.txt',
+            VersionData = Blob.valueOf('Test.jpg'),
+            IsMajorVersion = true
+        );
+        insert cv;
+    }
+
+    @IsTest
+    static void testLinkReplacement() {
+
+        ContentVersion cv = [SELECT Id FROM ContentVersion LIMIT 1];
+        String namespace = SummitEventsNamespace.getNamespace();
+
+        String rtfUrl = '<p><img src="https://example.force.com/sfc/servlet.shepherd/version/download/'
+            + cv.Id + '?versionId=' + cv.Id + '" alt="test"></img></p>';
+
+        Summit_Events__c se = new Summit_Events__c();
+        se.put(namespace + 'Event_Full_Text__c', rtfUrl);
+        se.put(namespace + 'Event_Name__c', 'Test Event');
+        se.put(namespace + 'Event_Status__c', 'Active');
+        se.put(namespace + 'Name', 'Test Event');
+        insert se;
+        se = [SELECT Event_Full_Text__c,Event_Name__c,Event_Status__c,Name FROM Summit_Events__c WHERE Id = :se.Id];
+
+
+        Map<Id, Summit_Events__c> newMap = new Map<Id, Summit_Events__c>{ se.Id => se };
+
+        Test.startTest();
+        SummitEventsRtfLinkPipeline rtfp = new SummitEventsRtfLinkPipeline(newMap);
+        rtfp.run();
+        Test.stopTest();
+
+        Summit_Events__c updated = [
+            SELECT Event_Full_Text__c,Event_Name__c,Event_Status__c,Name FROM Summit_Events__c WHERE Id = :se.Id
+        ];
+        ContentDistribution cd = [SELECT Id, DistributionPublicUrl FROM ContentDistribution WHERE ContentVersionId = :cv.Id LIMIT 1];
+        System.assert(!updated.Event_Full_Text__c.contains('versionId=068'));
+        System.assert(updated.Event_Full_Text__c.contains('https://'));
+        System.assert(updated.Event_Full_Text__c.contains(cd.DistributionPublicUrl));
+    }
+}
diff --git a/force-app/test/default/classes/SummitEventsRtfLinkPipeline_TEST.cls-meta.xml b/force-app/test/default/classes/SummitEventsRtfLinkPipeline_TEST.cls-meta.xml
new file mode 100644
index 00000000..82775b98
--- /dev/null
+++ b/force-app/test/default/classes/SummitEventsRtfLinkPipeline_TEST.cls-meta.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<ApexClass xmlns="http://soap.sforce.com/2006/04/metadata">
+    <apiVersion>65.0</apiVersion>
+    <status>Active</status>
+</ApexClass>