Add arduino examples

Author: sm-teknic

libraries/AnalogIO/AnalogIO-examples.h

@@ -0,0 +1,2 @@
+
+// This is just an empty header file to make this a valid Arduino library

libraries/AnalogIO/ReadAnalogInput/ReadAnalogInput.ino

@@ -0,0 +1,137 @@
+/*
+ * Title: ReadAnalogInput
+ *
+ * Objective:
+ *    This example demonstrates how to read the analog voltage of an analog
+ *    input. ClearCore analog inputs are natively compatible with 0-10V signals,
+ *    and 0-20mA signals with addition of an external resistor (see ClearCore
+ *    manual link below for wiring).
+ *
+ * Description:
+ *    This example sets up pin A-12 as an analog input, queries the value on
+ *    that connector every second, and calculates the input voltage. This
+ *    calculated voltage is written/displayed to the USB serial port.
+ *    Connectors IO-0 through IO-5 will act as a coarse meter of the voltage
+ *    read-in by turning on their outputs and LEDs (with more than 0V and less
+ *    than 2V, IO-0 will be on as an output. With ~2V and less than 4V, IO-0 and
+ *    IO-1 will be on; and so on until, with near 10V read in, IO-0 through IO-5
+ *    will be turned on).
+ *
+ * Requirements:
+ * ** An analog input source connected to A-12.
+ * ** Optional: LEDs connected to IO-0 through IO-5 to act as a more prominent
+ *    voltage meter than the ClearCore's onboard LEDs.
+ *
+ * Links:
+ * ** web link to doxygen (all Examples)
+ * ** web link to ClearCore Manual (all Examples)  <<FUTURE links to Getting started webpage/ ClearCore videos>>
+ *
+ * Last Modified: 1/21/2020
+ * Copyright (c) 2020 Teknic Inc. This work is free to use, copy and distribute under the terms of
+ * the standard MIT permissive software license which can be found at https://opensource.org/licenses/MIT
+ */
+
+// Defines the bit-depth of the ADC readings (8-bit, 10-bit, or 12-bit)
+// Supported adcResolution values are 8, 10, and 12
+#define adcResolution 12
+
+// Select the baud rate to match the target device.
+#define baudRate 9600
+
+void setup() {
+    // Put your setup code here, it will only run once:
+
+    // Initialize the serial port for printing analog voltage readings and wait
+    // up to 5 seconds for a port to open. Serial communication is not required
+    // for this example to run, however without it only the coarse LED meter
+    // can be used to read the analog signal.
+    Serial.begin(baudRate);
+    uint32_t timeout = 5000;
+    uint32_t startTime = millis();
+    while (!Serial && millis() - startTime < timeout) {
+        continue;
+    }
+
+    // Make a voltage meter display with the I/O pins.
+    pinMode(IO0, OUTPUT);
+    pinMode(IO1, OUTPUT);
+    pinMode(IO2, OUTPUT);
+    pinMode(IO3, OUTPUT);
+    pinMode(IO4, OUTPUT);
+    pinMode(IO5, OUTPUT);
+
+    // Clear out the state of our voltage meter to start.
+    digitalWrite(IO0, false);
+    digitalWrite(IO1, false);
+    digitalWrite(IO2, false);
+    digitalWrite(IO3, false);
+    digitalWrite(IO4, false);
+    digitalWrite(IO5, false);
+
+    // Since analog inputs default to analog input mode, there's no need to
+    // call pinMode().
+
+    // Set the resolution of the ADC.
+    analogReadResolution(adcResolution);
+}
+
+void loop() {
+    // Put your main code here, it will run repeatedly:
+
+    // Read the analog input (A-9 through A-12 may be configured as analog
+    // inputs).
+    int adcResult = analogRead(A12);
+    // Convert the reading to a voltage.
+    double inputVoltage = 10.0 * adcResult / ((1 << adcResolution) - 1);
+
+    // Alternatively, you can use the following to get a measurement in
+    // volts:
+    // inputVoltage = analogRead(A12, MILLIVOLTS) / 1000.0;
+
+    // Display the voltage reading to the USB serial port.
+    Serial.print("A-12 input voltage: ");
+    Serial.print(inputVoltage);
+    Serial.println("V.");
+
+    // Write the voltage reading to the voltage meter display pins
+    // (IO-0 through IO-5).
+    if (inputVoltage > 0.1) {
+        digitalWrite(IO0, true);
+    }
+    else {
+        digitalWrite(IO0, false);
+    }
+    if (inputVoltage > 2.0) {
+        digitalWrite(IO1, true);
+    }
+    else {
+        digitalWrite(IO1, false);
+    }
+    if (inputVoltage > 4.0) {
+        digitalWrite(IO2, true);
+    }
+    else {
+        digitalWrite(IO2, false);
+    }
+    if (inputVoltage > 6.0) {
+        digitalWrite(IO3, true);
+    }
+    else {
+        digitalWrite(IO3, false);
+    }
+    if (inputVoltage > 8.0) {
+        digitalWrite(IO4, true);
+    }
+    else {
+        digitalWrite(IO4, false);
+    }
+    if (inputVoltage >= 9.9) {
+        digitalWrite(IO5, true);
+    }
+    else {
+        digitalWrite(IO5, false);
+    }
+
+    // Wait a second before the next reading.
+    delay(1000);
+}

libraries/AnalogIO/WriteAnalogCurrentOutput/WriteAnalogCurrentOutput.ino

@@ -0,0 +1,52 @@
+/*
+ * Title: WriteAnalogCurrentOutput
+ *
+ * Objective:
+ *    This example demonstrates how to write analog current values to an analog
+ *    current output connector.
+ *
+ * Description:
+ *    This example configures pin IO-0 as an analog current output. It outputs
+ *    a repeating analog signal, starting at 0mA, increasing to 20mA, and
+ *    decreasing back to 0mA.
+ *
+ * Requirements:
+ * ** Connect a device to IO-0 which takes in analog current.
+ *
+ * Links:
+ * ** web link to doxygen (all Examples)
+ * ** web link to ClearCore Manual (all Examples)  <<FUTURE links to Getting started webpage/ ClearCore videos>>
+ *
+ * Last Modified: 1/21/2020
+ * Copyright (c) 2020 Teknic Inc. This work is free to use, copy and distribute under the terms of
+ * the standard MIT permissive software license which can be found at https://opensource.org/licenses/MIT
+ */
+
+
+void setup() {
+    // Put your setup code here, it will run once:
+
+    // Set up connector IO-0 to be an output. We will specify that it outputs
+    // current in our analogWrite functions later (as opposed to a digital
+    // signal or PWM).
+    // Note that only connector IO-0 is capable of analog current output.
+    pinMode(IO0, OUTPUT);
+}
+
+void loop() {
+    // Put your main code here, it will run repeatedly:
+
+    // Ramp the current output of IO-0 up to 20mA.
+    for (uint16_t value = 0; value < 2047; value++) {
+        // ClearCore's analog current output has 11-bit resolution, so we write
+        // values of 0 to 2047 (corresponding to 0-20mA).
+        analogWrite(IO0, value, CURRENT);
+        delay(2);
+    }
+
+    // Ramp the current output of IO-0 back down.
+    for (uint16_t value = 0; value < 2047; value++) {
+        analogWrite(IO0, 2047 - value, CURRENT);
+        delay(2);
+    }
+}

libraries/AnalogIO/WritePwmOutput/WritePwmOutput.ino

@@ -0,0 +1,57 @@
+/*
+ * Title: WritePwmOutput
+ *
+ * Objective:
+ *    This example demonstrates how to write a digital PWM signal to a ClearCore
+ *    digital output.
+ *
+ * Description:
+ *    This example sets the defined pin as an output then writes a series of
+ *    PWM signals with varying duty cycles to the output.
+ *
+ * Requirements:
+ * ** Connect a device that takes in a PWM signal to IO-1
+ *
+ * Links:
+ * ** web link to doxygen (all Examples)
+ * ** web link to ClearCore Manual (all Examples)  <<FUTURE links to Getting started webpage/ ClearCore videos>>
+ *
+ * Last Modified: 1/21/2020
+ * Copyright (c) 2020 Teknic Inc. This work is free to use, copy and distribute under the terms of
+ * the standard MIT permissive software license which can be found at https://opensource.org/licenses/MIT
+ */
+
+// Specify which output pin to write digital PWM to.
+// PWM-capable pins: IO-0 through IO-5.
+// Note: IO-4 and IO-5 are capable of bi-directional and higher-current PWM
+//       output using an H-Bridge. See the WriteHBridgeOutput example.
+#define outputPin IO1
+
+void setup() {
+    // Put your setup code here, it will run once:
+
+    // Set up the output pin to be an output
+    pinMode(outputPin, OUTPUT);
+}
+
+void loop() {
+    // Put your main code here, it will run repeatedly:
+
+    // Write some digital PWM signals to the output connector.
+    // Note: analogWrite() is the Arduino wrapper function used to write PWM,
+    // despite the fact that it is not a "true" analog signal
+    // Valid values range from 0 (0% duty cycle / always off)
+    // to 255 (100% duty cycle / always on).
+
+    // Output a low duty cycle for 1 second.
+    analogWrite(outputPin, 10);
+    delay(1000);
+
+    // Output a medium duty cycle for 1 second.
+    analogWrite(outputPin, 120);
+    delay(1000);
+
+    // Output a high duty cycle for 1 second.
+    analogWrite(outputPin, 230);
+    delay(1000);
+}

libraries/AnalogIO/library.properties

@@ -0,0 +1,9 @@
+name=Analog I/O
+version=1.0.0
+author=Teknic
+maintainer=Teknic <sales@teknic.com>
+sentence=Teknic Analog I/O Examples
+paragraph=Teknic Analog I/O Examples
+category=Device Control
+url=https://github.com/Teknic-Inc/ClearCore-Arduino-wrapper
+architectures=sam