Add :duct.session-store/cookie component

Add a :duct.session-store/cookie component that implements the standard
Ring cookie session store. Includes support for re-using the cookie
store across resets, and for parsing the key from a hex-encoded string.

Author: weavejester

project.clj

@@ -8,6 +8,7 @@
                  [org.duct-framework/handler "0.1.4"]
                  [org.duct-framework/server.http.jetty "0.3.4"]
                  [org.duct-framework/router.reitit "0.5.2"]
+                 [commons-io "2.20.0"]
                  [com.rpl/specter "1.1.6"]
                  [integrant "1.0.1"]
                  [hiccup "2.0.0"]

src/duct/session_store/cookie.clj

@@ -0,0 +1,20 @@
+(ns duct.session-store.cookie
+  (:require [integrant.core :as ig]
+            [ring.middleware.session.cookie :as cookie])
+  (:import [org.apache.commons.codec.binary Hex]))
+
+(defmethod ig/assert-key :duct.session-store/cookie [_ {:keys [key]}]
+  (assert (or (nil? key)
+              (and (string? key) (re-matches #"[0-9a-fA-F]{32}" key)))
+          ":key should be nil or a randomly generated 16-byte hex string"))
+
+(defmethod ig/init-key :duct.session-store/cookie [_ {:keys [key]}]
+  (if (some? key)
+    (cookie/cookie-store {:key (Hex/decodeHex ^String key)})
+    (cookie/cookie-store)))
+
+(defmethod ig/resume-key :duct.session-store/cookie 
+  [k opts old-opts old-store]
+  (if (= opts old-opts)
+    old-store
+    (ig/init-key k opts)))

test/duct/session_store/cookie_test.clj

@@ -0,0 +1,36 @@
+(ns duct.session-store.cookie-test
+  (:require [clojure.test :refer [deftest is testing]]
+            [duct.session-store.cookie]
+            [integrant.core :as ig]
+            [ring.middleware.session.store :as store]))
+
+(deftest cookie-store-test
+  (testing "bad :key option"
+    (is (thrown? clojure.lang.ExceptionInfo
+                 (ig/init {:duct.session-store/cookie {:key "x"}}))))
+  (testing "init produces session store"
+    (let [system (ig/init {:duct.session-store/cookie {}})]
+      (is (satisfies? store/SessionStore
+                      (:duct.session-store/cookie system))))
+    (let [system (ig/init {:duct.session-store/cookie
+                           {:key "00112233445566778899aabbccddeeff"}})]
+      (is (satisfies? store/SessionStore
+                      (:duct.session-store/cookie system)))))
+  (testing "resume uses old store if options unchanged"
+    (let [config {:duct.session-store/cookie {}} 
+          system (ig/init config)]
+      (ig/suspend! system)
+      (let [new-system (ig/resume config system)]
+        (is (identical? (:duct.session-store/cookie system)
+                        (:duct.session-store/cookie new-system))))))
+  (testing "resume uses new store if options changed"
+    (let [config {:duct.session-store/cookie {}} 
+          system (ig/init config)]
+      (ig/suspend! system)
+      (let [new-config {:duct.session-store/cookie
+                        {:key "00112233445566778899aabbccddeeff"}}
+            new-system (ig/resume new-config system)]
+        (is (satisfies? store/SessionStore
+                        (:duct.session-store/cookie new-system)))
+        (is (not (identical? (:duct.session-store/cookie system)
+                             (:duct.session-store/cookie new-system))))))))