Introduce Mix.State to store internal mix state

Moves non-config state from application env to an ETS table that is
updated with an Agent.

Author: fishcakez

lib/mix/lib/mix.ex

@@ -161,27 +161,37 @@ defmodule Mix do
   def start(_type, []) do
     import Supervisor.Spec
 
+    state = [shell: Mix.Shell.IO,
+             env: String.to_atom(System.get_env("MIX_ENV") || "dev"),
+             scm: [Mix.SCM.Git, Mix.SCM.Path]]
+    tab = Mix.State.new(state)
     children = [
+      worker(Mix.State, [tab]),
       worker(Mix.TasksServer, []),
       worker(Mix.ProjectStack, [])
     ]
 
     opts = [strategy: :one_for_one, name: Mix.Supervisor]
-    stat = Supervisor.start_link(children, opts)
-
-    if env = System.get_env("MIX_ENV") do
-      env(String.to_atom env)
+    case Supervisor.start_link(children, opts) do
+      {:ok, pid} ->
+        {:ok, pid, tab}
+      {:error, _} = error ->
+        Mix.State.delete(tab)
+        error
     end
+  end
 
-    stat
+  @doc false
+  def stop(tab) do
+    Mix.State.delete(tab)
   end
 
   @doc """
   Returns the mix environment.
   """
   def env do
     # env is not available on bootstrapping, so set a :dev default
-    Application.get_env(:mix, :env, :dev)
+    Mix.State.get(:env, :dev)
   end
 
   @doc """
@@ -191,7 +201,7 @@ defmodule Mix do
   configuration won't be reloaded.
   """
   def env(env) when is_atom(env) do
-    Application.put_env(:mix, :env, env)
+    Mix.State.put(:env, env)
   end
 
   @doc """
@@ -218,14 +228,14 @@ defmodule Mix do
   messages to the current process.
   """
   def shell do
-    Application.get_env(:mix, :shell, Mix.Shell.IO)
+    Mix.State.get(:shell, Mix.Shell.IO)
   end
 
   @doc """
   Sets the current shell.
   """
   def shell(shell) do
-    Application.put_env(:mix, :shell, shell)
+    Mix.State.put(:shell, shell)
   end
 
   @doc """

lib/mix/lib/mix/remote_converger.ex

@@ -30,13 +30,13 @@ defmodule Mix.RemoteConverger do
   Get registered remote converger.
   """
   def get do
-    Application.get_env(:mix, :remote_converger)
+    Mix.State.get(:remote_converger)
   end
 
   @doc """
   Register a remote converger.
   """
   def register(mod) when is_atom(mod) do
-    Application.put_env(:mix, :remote_converger, mod)
+    Mix.State.put(:remote_converger, mod)
   end
 end

lib/mix/lib/mix/scm.ex

@@ -116,23 +116,21 @@ defmodule Mix.SCM do
   until a matching one is found.
   """
   def available do
-    {:ok, scm} = Application.fetch_env(:mix, :scm)
+    {:ok, scm} = Mix.State.fetch(:scm)
     scm
   end
 
   @doc """
   Prepend the given SCM module to the list of available SCMs.
   """
   def prepend(mod) when is_atom(mod) do
-    available = Enum.reject(available(), &(&1 == mod))
-    Application.put_env(:mix, :scm, [mod|available])
+    Mix.State.prepend(:scm, mod)
   end
 
   @doc """
   Append the given SCM module to the list of available SCMs.
   """
   def append(mod) when is_atom(mod) do
-    available = Enum.reject(available(), &(&1 == mod))
-    Application.put_env(:mix, :scm, available ++ [mod])
+    Mix.State.append(:scm, mod)
   end
 end

lib/mix/lib/mix/scm/git.ex

@@ -163,12 +163,12 @@ defmodule Mix.SCM.Git do
   end
 
   defp assert_git do
-    case Application.fetch_env(:mix, :git_available) do
+    case Mix.State.fetch(:git_available) do
       {:ok, true} ->
         :ok
       :error ->
         if :os.find_executable('git') do
-          Application.put_env(:mix, :git_available, true)
+          Mix.State.put(:git_available, true)
         else
           Mix.raise "Error fetching/updating Git repository: the `git` "  <>
             "executable is not available in your PATH. Please install "   <>
@@ -179,7 +179,7 @@ defmodule Mix.SCM.Git do
   end
 
   defp git_version do
-    case Application.fetch_env(:mix, :git_version) do
+    case Mix.State.fetch(:git_version) do
       {:ok, version} ->
         version
       :error ->
@@ -189,7 +189,7 @@ defmodule Mix.SCM.Git do
           |> String.strip
           |> parse_version
 
-        Application.put_env(:mix, :git_version, version)
+        Mix.State.put(:git_version, version)
         version
     end
   end

lib/mix/lib/mix/state.ex

@@ -0,0 +1,79 @@
+defmodule Mix.State do
+  @moduledoc false
+
+  @table __MODULE__
+  @agent __MODULE__
+
+  def new(state) do
+    tab = :ets.new(@table, [:named_table, :public])
+    true = :ets.insert_new(@table, state)
+    tab
+  end
+
+  def delete(@table = tab) do
+    :ets.delete(tab)
+  end
+
+  def start_link(tab) do
+    Agent.start_link(__MODULE__, :init, [tab], [name: @agent])
+  end
+
+  def init(@table = tab) do
+    case :ets.info(tab, :protection) do
+      :public ->
+        tab
+      :undefined ->
+        raise "#{tab} does not exist"
+      _ ->
+        raise "#{tab} is not public"
+    end
+  end
+
+  def fetch(key) do
+    case :ets.lookup(@table, key) do
+      [{_, value}] ->
+        {:ok, value}
+      [] ->
+        :error
+    end
+  end
+
+  def get(key, default \\ nil) do
+    case fetch(key) do
+      {:ok, value} -> value
+      :error       -> default
+    end
+  end
+
+  def put(key, value) do
+    Agent.update(@agent, __MODULE__, :handle_put, [key, value])
+  end
+
+  def handle_put(tab, key, value) do
+    true = :ets.insert(tab, {key, value})
+    tab
+  end
+
+  def prepend(key, value) do
+    Agent.update(@agent, __MODULE__, :handle_prepend, [key, value])
+  end
+
+  def handle_prepend(tab, key, value) do
+    true = :ets.insert(tab, {key, [value | reject(key, value)]})
+    tab
+  end
+
+  def append(key, value) do
+    Agent.update(@agent, __MODULE__, :handle_append, [key, value])
+  end
+
+  def handle_append(tab, key, value) do
+    true = :ets.insert(tab, {key, reject(key, value) ++ [value]})
+    tab
+  end
+
+  defp reject(key, value) do
+    {:ok, list} = fetch(key)
+    Enum.reject(list, &(&1 === value))
+  end
+end

lib/mix/mix.exs

@@ -9,11 +9,8 @@ defmodule Mix.Mixfile do
   end
 
   def application do
-    [registered: [Mix.TasksServer, Mix.ProjectStack],
+    [registered: [Mix.State, Mix.TasksServer, Mix.ProjectStack],
      mod: {Mix, []},
-     env: [shell: Mix.Shell.IO,
-           env: :dev,
-           scm: [Mix.SCM.Git, Mix.SCM.Path],
-           colors: []]]
+     env: [colors: []]]
   end
 end

lib/mix/test/mix/rebar_test.exs

@@ -18,8 +18,8 @@ defmodule Mix.RebarTest do
 
   setup do
     available = Mix.SCM.available
-    Application.put_env(:mix, :scm, [Mix.SCM.Git, MyPath])
-    on_exit fn -> Application.put_env(:mix, :scm, available) end
+    Mix.State.put(:scm, [Mix.SCM.Git, MyPath])
+    on_exit fn -> Mix.State.put(:scm, available) end
     :ok
   end
 

lib/mix/test/mix/scm_test.exs

@@ -5,7 +5,7 @@ defmodule Mix.SCMTest do
 
   setup do
     available = Mix.SCM.available
-    on_exit fn -> Application.put_env(:mix, :scm, available) end
+    on_exit fn -> Mix.State.put(:scm, available) end
     :ok
   end