Do not match files starting with . in Path.wildcard/2 by default

Author: José Valim

lib/elixir/lib/path.ex

@@ -483,6 +483,32 @@ defmodule Path do
     FN.split(IO.chardata_to_string(path))
   end
 
+  defmodule Wildcard do
+    @moduledoc false
+
+    def read_file_info(file) do
+      call({:read_link_info, file})
+    end
+
+    def list_dir(dir) do
+      case call({:list_dir, dir})  do
+        {:ok, files} ->
+          {:ok, for(file <- files, hd(file) != ?., do: file)}
+        other ->
+          other
+      end
+    end
+
+    @compile {:inline, call: 1}
+
+    defp call(tuple) do
+      x = :erlang.dt_spread_tag(true)
+      y = :gen_server.call(:file_server_2, tuple)
+      :erlang.dt_restore_tag(x)
+      y
+    end
+  end
+
   @doc """
   Traverses paths according to the given `glob` expression.
 
@@ -503,6 +529,9 @@ defmodule Path do
   exactly the same character in the same position will match. Note
   that matching is case-sensitive; i.e. "a" will not match "A".
 
+  By default, the patterns `*` and `?` do not match files starting
+  with a dot `.` unless `match_dot: true` is given.
+
   ## Examples
 
   Imagine you have a directory called `projects` with three Elixir projects
@@ -517,10 +546,11 @@ defmodule Path do
 
   """
   @spec wildcard(t) :: [binary]
-  def wildcard(glob) do
+  def wildcard(glob, opts \\ []) do
+    mod = if Keyword.get(opts, :match_dot), do: :file, else: Path.Wildcard
     glob
-    |> chardata_to_list
-    |> :filelib.wildcard
+    |> chardata_to_list()
+    |> :filelib.wildcard(mod)
     |> Enum.map(&IO.chardata_to_string/1)
   end
 
@@ -552,7 +582,7 @@ defmodule Path do
     normalize t, acc
   end
 
-  defp normalize([".."|t], [<<_letter, ?:, ?/>>|_] = acc) when _letter in ?a..?z do
+  defp normalize([".."|t], [<<letter, ?:, ?/>>|_] = acc) when letter in ?a..?z do
     normalize t, acc
   end
 

lib/elixir/test/elixir/path_test.exs

@@ -5,14 +5,30 @@ defmodule PathTest do
   import PathHelpers
 
   if :file.native_name_encoding == :utf8 do
-    test :wildcard do
+    test :wildcard_with_utf8 do
       File.mkdir_p(tmp_path("héllò"))
       assert Path.wildcard(tmp_path("héllò")) == [tmp_path("héllò")]
     after
       File.rm_rf tmp_path("héllò")
     end
   end
 
+  test :wildcard do
+    hello = tmp_path("wildcard/.hello")
+    world = tmp_path("wildcard/.hello/world")
+    File.mkdir_p(world)
+
+    assert Path.wildcard(tmp_path("wildcard/*/*")) == []
+    assert Path.wildcard(tmp_path("wildcard/**/*")) == []
+    assert Path.wildcard(tmp_path("wildcard/?hello/world")) == []
+
+    assert Path.wildcard(tmp_path("wildcard/*/*"), match_dot: true) == [world]
+    assert Path.wildcard(tmp_path("wildcard/**/*"), match_dot: true) == [hello, world]
+    assert Path.wildcard(tmp_path("wildcard/?hello/world"), match_dot: true) == [world]
+  after
+    File.rm_rf tmp_path("wildcard")
+  end
+
   if is_win? do
     test :relative do
       assert Path.relative("C:/usr/local/bin")    == "usr/local/bin"

lib/mix/lib/mix/utils.ex

@@ -108,8 +108,6 @@ defmodule Mix.Utils do
   the return result. If it is a directory, it is searched
   recursively for files with the given extensions or matching
   the given patterns.
-
-  Any file starting with `"."` is ignored.
   """
   def extract_files(paths, exts_or_pattern)
 
@@ -118,15 +116,9 @@ defmodule Mix.Utils do
   end
 
   def extract_files(paths, pattern) do
-    files = Enum.flat_map(paths, fn path ->
+    Enum.flat_map(paths, fn path ->
       if File.regular?(path), do: [path], else: Path.wildcard("#{path}/**/#{pattern}")
-    end)
-    files |> exclude_files |> Enum.uniq
-  end
-
-  defp exclude_files(files) do
-    filter = fn(x) -> not match?("." <> _, Path.basename(x)) end
-    Enum.filter files, filter
+    end) |> Enum.uniq
   end
 
   @doc """