Remove regexes from ExUnit, IEx and Mix

Author: José Valim

lib/ex_unit/lib/ex_unit/doc_test.ex

@@ -426,7 +426,7 @@ defmodule ExUnit.DocTest do
   end
 
   defp extract_tests(line_no, doc, module) do
-    all_lines = String.split(doc, ~r/\n/, trim: false)
+    all_lines = String.split(doc, "\n", trim: false)
     lines = adjust_indent(all_lines, line_no + 1, module)
     extract_tests(lines, "", "", [], true, module)
   end
@@ -626,11 +626,29 @@ defmodule ExUnit.DocTest do
         [mod, message] = :binary.split(error, ")")
         {:error, Module.concat([mod]), String.trim_leading(message)}
       _ ->
-        if string =~ ~r/\A#[A-Z][\w\.]*</mu do
+        if is_inspected?(string) do
           {:inspect, inspect(string)}
         else
           {:test, string}
         end
     end
   end
+
+  defp is_inspected?(<<?#, char, rest::binary>>) when char in ?A..?Z,
+    do: is_inspected_end?(rest)
+  defp is_inspected?(_),
+    do: false
+
+  defp is_inspected_end?(<<?., char, rest::binary>>) when char in ?A..?Z,
+    do: is_inspected_end?(rest)
+  defp is_inspected_end?(<<char, rest::binary>>)
+       when char in ?A..?Z
+       when char in ?a..?z
+       when char in ?0..?9
+       when char == ?_,
+    do: is_inspected_end?(rest)
+  defp is_inspected_end?(<<?<, _::binary>>),
+    do: true
+  defp is_inspected_end?(_),
+    do: false
 end

lib/ex_unit/lib/ex_unit/filters.ex

@@ -14,10 +14,11 @@ defmodule ExUnit.Filters do
   """
   @spec parse_path(String.t) :: {String.t, any}
   def parse_path(file) do
-    case Regex.run(~r/^(.+):(\d+)$/, file, capture: :all_but_first) do
-      [file, line_number] ->
-        {file, exclude: [:test], include: [line: line_number]}
-      nil ->
+    {paths, [line]} = file |> String.split(":") |> Enum.split(-1)
+    case Integer.parse(line) do
+      {_, ""} ->
+        {Enum.join(paths, ":"), exclude: [:test], include: [line: line]}
+      _ ->
         {file, []}
     end
   end

lib/iex/lib/iex/server.ex

@@ -269,7 +269,11 @@ defmodule IEx.Server do
 
   defp allow_take?(identifier) do
     message = IEx.color(:eval_interrupt, "#{identifier}\nAllow? [Yn] ")
-    IO.gets(:stdio, message) =~ ~r/^(Y(es)?)?$/i
+    yes?(IO.gets(:stdio, message))
+  end
+
+  defp yes?(string) do
+    is_binary(string) and String.trim(string) in ["", "y", "Y", "yes", "YES", "Yes"]
   end
 
   ## State

lib/mix/lib/mix/shell/io.ex

@@ -46,31 +46,27 @@ defmodule Mix.Shell.IO do
   end
 
   @doc """
-  Prints a message and prompts the user for
-  input. Input will be consumed until Enter is pressed.
+  Prints a message and prompts the user for input.
+
+  Input will be consumed until Enter is pressed.
   """
   def prompt(message) do
     print_app()
-    IO.gets message <> " "
+    IO.gets(message <> " ")
   end
 
   @doc """
   Prints a message and asks the user if they want to proceed.
-  The user must press Enter or type anything that matches the "yes"
-  regex `~r/^Y(es)?$/i`.
+
+  The user must press Enter or type one of "y", "yes", "Y", "YES" or
+  "Yes".
   """
   def yes?(message) do
     print_app()
-    got_yes? IO.gets(message <> " [Yn] ")
+    answer = IO.gets(message <> " [Yn] ")
+    is_binary(answer) and String.trim(answer) in ["", "y", "Y", "yes", "YES", "Yes"]
   end
 
-  defp got_yes?(answer) when is_binary(answer) do
-    answer =~ ~r/^(Y(es)?)?$/i
-  end
-
-  # The IO server may return :eof or :error
-  defp got_yes?(_), do: false
-
   defp red(message) do
     [:red, :bright, message]
   end

lib/mix/lib/mix/shell/quiet.ex

@@ -32,15 +32,17 @@ defmodule Mix.Shell.Quiet do
   defdelegate error(message), to: Mix.Shell.IO
 
   @doc """
-  Prints a message and prompts the user for
-  input. Input will be consumed until Enter is pressed.
+  Prints a message and prompts the user for input.
+
+  Input will be consumed until Enter is pressed.
   """
   defdelegate prompt(message), to: Mix.Shell.IO
 
   @doc """
-  Receives a message and asks the user if they want to proceed.
-  The user must press enter or type anything that matches the "yes"
-  regex `~r/^Y(es)?$/i`.
+  Prints a message and asks the user if they want to proceed.
+
+  The user must press Enter or type one of "y", "yes", "Y", "YES" or
+  "Yes".
   """
   defdelegate yes?(message), to: Mix.Shell.IO
 end

lib/mix/lib/mix/tasks/new.ex

@@ -158,7 +158,7 @@ defmodule Mix.Tasks.New do
   end
 
   defp check_application_name!(name, inferred?) do
-    unless name =~ ~r/^[a-z][\w_]*$/ do
+    unless name =~ Regex.recompile!(~r/^[a-z][a-z0-9_]*$/) do
       Mix.raise "Application name must start with a letter and have only lowercase " <>
                 "letters, numbers and underscore, got: #{inspect name}" <>
                 (if inferred? do
@@ -171,7 +171,7 @@ defmodule Mix.Tasks.New do
   end
 
   defp check_mod_name_validity!(name) do
-    unless name =~ ~r/^[A-Z]\w*(\.[A-Z]\w*)*$/ do
+    unless name =~ Regex.recompile!(~r/^[A-Z]\w*(\.[A-Z]\w*)*$/) do
       Mix.raise "Module name must be a valid Elixir alias (for example: Foo.Bar), got: #{inspect name}"
     end
   end