take first term in bracket

[veretin]

Hi!

A following task appear. Given some cfun A(?a). I want to bracket A, and take from each
bracket one element (which one is not important).
I can do this with preprocessor #do-loop. But is it possible to do it without that?

Best regards,
Oleg Veretin

[jodavies]

Does something like this do the job?

CFunction A,coll,COLL;
Symbol x;

Local test = (<A(1)>+...+<A(10)>)*(<x^1>+...+<x^10>);

Bracket A;
.sort
Collect coll,COLL;

Identify COLL(x?) = 0;
SplitArg coll;
Identify coll(x?,?a) = x;

Print +s;
.end

[veretin]

No, terms are very large by themselves (graphs). Collect is not a good solution.
I try something like this: enumerate terms in brackets and take first.

bracket A;
.sort

keep brackets;
#$x = 0;
$x = $x + 1;
multiply I($x);
.sort

But this does not work. "I" operates on the whole bracket but not on its content.

[veretin]

In principle your solution works even with large terms. Still I would like to enumerate terms in bracket, also for other algorithms.

[jodavies]

Right, this is the point of the second CFunction of the Collect, which contains the "overflow". I suppose one can enumerate the terms by taking the i-th function argument (and making sure there is no overflow, by setting MaxTermSize sufficiently large) using transform selectargs.

[tueda]

This recipe may be helpful:

CF A;
S x;
L F = (<A(1)>+...+<A(10)>)*(<x^1>+...+<x^10>);
B A;
P;
.sort

Keep Brackets;

id A(?a) = A(A(?a));
#define start "{`extrasymbols_'+1}"
argtoextrasymbol tonumber, A;

B +A;
P;
.sort

CF B;
Drop;

#define end "`extrasymbols_'"

* split bracket contents into new expressions
L F = <extrasymbol_(`start') * B(`start')>+...+<extrasymbol_(`end') * B(`end')>;
#do i=`start',`end'
  L B`i' = F[A(`i')];
#enddo

.sort

* get first terms
#do i=`start',`end'
  L FB`i' = firstterm_(B`i');
#enddo

P;
.sort

Drop;
Ndrop F;

* convert back to the original form
#do i=`start',`end'
  id B(`i') = B`i';
#enddo
B A;
P;
.end