Merge pull request #10226 from github/redsun82/swift-generate-printast

Swift: add `PrintAst`

Author: MathiasVP

config/identical-files.json

@@ -584,19 +584,19 @@
   ],
   "Swift declarations test file": [
     "swift/ql/test/extractor-tests/declarations/declarations.swift",
-    "swift/ql/test/library-tests/parent/declarations.swift"
+    "swift/ql/test/library-tests/ast/declarations.swift"
   ],
   "Swift statements test file": [
     "swift/ql/test/extractor-tests/statements/statements.swift",
-    "swift/ql/test/library-tests/parent/statements.swift"
+    "swift/ql/test/library-tests/ast/statements.swift"
   ],
   "Swift expressions test file": [
     "swift/ql/test/extractor-tests/expressions/expressions.swift",
-    "swift/ql/test/library-tests/parent/expressions.swift"
+    "swift/ql/test/library-tests/ast/expressions.swift"
   ],
   "Swift patterns test file": [
     "swift/ql/test/extractor-tests/patterns/patterns.swift",
-    "swift/ql/test/library-tests/parent/patterns.swift"
+    "swift/ql/test/library-tests/ast/patterns.swift"
   ],
   "IncompleteMultiCharacterSanitization JS/Ruby": [
     "javascript/ql/lib/semmle/javascript/security/IncompleteMultiCharacterSanitizationQuery.qll",

swift/codegen/schema.yml

@@ -60,7 +60,8 @@ Type:
   canonical_type: Type
 
 IterableDeclContext:
-  members: Decl*
+  _children:
+    members: Decl*
 
 ExtensionDecl:
   extended_type_decl: NominalTypeDecl
@@ -293,8 +294,7 @@ TypeAliasType:
 
 EnumCaseDecl:
   _extends: Decl
-  _children:
-    elements: EnumElementDecl*
+  elements: EnumElementDecl*
 
 IfConfigDecl:
   _extends: Decl
@@ -836,8 +836,7 @@ PrefixUnaryExpr:
 
 SelfApplyExpr:
   _extends: ApplyExpr
-  _children:
-    base: Expr
+  base: Expr
 
 ArrayExpr:
   _extends: CollectionExpr

swift/ql/lib/codeql/swift/elements/expr/ArgumentConstructor.qll

@@ -1,4 +1,9 @@
-// generated by codegen/codegen.py, remove this comment if you wish to edit this file
 private import codeql.swift.generated.Raw
 
-predicate constructArgument(Raw::Argument id) { any() }
+predicate constructArgument(Raw::Argument id) {
+  // exclude an argument that will be part of a DotSyntaxCallExpr
+  // that will be transformed into a MethodRefCallExpr
+  not exists(Raw::DotSyntaxCallExpr c |
+    c.getFunction() instanceof Raw::DeclRefExpr and id = c.getArgument(0)
+  )
+}

swift/ql/lib/codeql/swift/elements/expr/DeclRefExprConstructor.qll

@@ -1,4 +1,7 @@
-// generated by codegen/codegen.py, remove this comment if you wish to edit this file
 private import codeql.swift.generated.Raw
 
-predicate constructDeclRefExpr(Raw::DeclRefExpr id) { any() }
+predicate constructDeclRefExpr(Raw::DeclRefExpr id) {
+  // exclude an argument that will be part of a DotSyntaxCallExpr
+  // that will be transformed into a MethodRefCallExpr
+  not exists(Raw::DotSyntaxCallExpr c | id = c.getFunction())
+}

swift/ql/lib/codeql/swift/generated/ParentChild.qll

@@ -60,14 +60,18 @@ private module Impl {
   private Element getImmediateChildOfIterableDeclContext(
     IterableDeclContext e, int index, string partialPredicateCall
   ) {
-    exists(int b, int bElement, int n |
+    exists(int b, int bElement, int n, int nMember |
       b = 0 and
       bElement = b + 1 + max(int i | i = -1 or exists(getImmediateChildOfElement(e, i, _)) | i) and
       n = bElement and
+      nMember = n + 1 + max(int i | i = -1 or exists(e.getImmediateMember(i)) | i) and
       (
         none()
         or
         result = getImmediateChildOfElement(e, index - b, partialPredicateCall)
+        or
+        result = e.getImmediateMember(index - n) and
+        partialPredicateCall = "Member(" + (index - n).toString() + ")"
       )
     )
   }
@@ -1562,18 +1566,14 @@ private module Impl {
   private Element getImmediateChildOfEnumCaseDecl(
     EnumCaseDecl e, int index, string partialPredicateCall
   ) {
-    exists(int b, int bDecl, int n, int nElement |
+    exists(int b, int bDecl, int n |
       b = 0 and
       bDecl = b + 1 + max(int i | i = -1 or exists(getImmediateChildOfDecl(e, i, _)) | i) and
       n = bDecl and
-      nElement = n + 1 + max(int i | i = -1 or exists(e.getImmediateElement(i)) | i) and
       (
         none()
         or
         result = getImmediateChildOfDecl(e, index - b, partialPredicateCall)
-        or
-        result = e.getImmediateElement(index - n) and
-        partialPredicateCall = "Element(" + (index - n).toString() + ")"
       )
     )
   }
@@ -3970,17 +3970,14 @@ private module Impl {
   private Element getImmediateChildOfSelfApplyExpr(
     SelfApplyExpr e, int index, string partialPredicateCall
   ) {
-    exists(int b, int bApplyExpr, int n, int nBase |
+    exists(int b, int bApplyExpr, int n |
       b = 0 and
       bApplyExpr = b + 1 + max(int i | i = -1 or exists(getImmediateChildOfApplyExpr(e, i, _)) | i) and
       n = bApplyExpr and
-      nBase = n + 1 and
       (
         none()
         or
         result = getImmediateChildOfApplyExpr(e, index - b, partialPredicateCall)
-        or
-        index = n and result = e.getImmediateBase() and partialPredicateCall = "Base()"
       )
     )
   }

swift/ql/lib/codeql/swift/printast/PrintAst.qll

@@ -0,0 +1,49 @@
+/**
+ * Provides queries to pretty-print a Go AST as a graph.
+ */
+
+import PrintAstNode
+
+cached
+private int getOrder(PrintAstNode node) {
+  node =
+    rank[result](PrintAstNode n, Location loc |
+      loc = n.getLocation()
+    |
+      n
+      order by
+        loc.getFile().getName(), loc.getStartLine(), loc.getStartColumn(), loc.getEndLine(),
+        loc.getEndColumn()
+    )
+}
+
+/** Holds if `node` belongs to the output tree, and its property `key` has the given `value`. */
+query predicate nodes(PrintAstNode node, string key, string value) {
+  node.shouldBePrinted() and
+  (
+    key = "semmle.label" and value = node.toString()
+    or
+    key = "semmle.order" and value = getOrder(node).toString()
+    or
+    value = node.getProperty(key)
+  )
+}
+
+/**
+ * Holds if `target` is a child of `source` in the AST, and property `key` of the edge has the
+ * given `value`.
+ */
+query predicate edges(PrintAstNode source, PrintAstNode target, string key, string value) {
+  source.shouldBePrinted() and
+  target.shouldBePrinted() and
+  exists(int index, string accessor | source.hasChild(target, index, accessor) |
+    key = "semmle.label" and value = accessor
+    or
+    key = "semmle.order" and value = index.toString()
+  )
+}
+
+/** Holds if property `key` of the graph has the given `value`. */
+query predicate graphProperties(string key, string value) {
+  key = "semmle.graphKind" and value = "tree"
+}

swift/ql/lib/codeql/swift/printast/PrintAstNode.qll

@@ -0,0 +1,86 @@
+/**
+ * Provides classes used to pretty-print a Go AST as a graph.
+ * This is factored out of `PrintAst.qll` for testing purposes.
+ */
+
+import swift
+import codeql.swift.generated.ParentChild
+
+private newtype TPrintAstConfiguration = TMakePrintAstConfiguration()
+
+/**
+ * The hook to customize the files and functions printed by this module.
+ */
+class PrintAstConfiguration extends TPrintAstConfiguration {
+  /**
+   * Gets the string representation of this singleton
+   */
+  string toString() { result = "PrintAstConfiguration" }
+
+  /**
+   * Holds if the AST for `e` should be printed. By default, holds for all.
+   */
+  predicate shouldPrint(Locatable e) { any() }
+}
+
+private predicate shouldPrint(Locatable e) { any(PrintAstConfiguration config).shouldPrint(e) }
+
+/**
+ * An AST node that should be printed.
+ */
+private newtype TPrintAstNode =
+  TLocatable(Locatable ast) {
+    // Only consider resolved nodes (that is not within the hidden conversion AST)
+    ast = ast.resolve()
+  }
+
+/**
+ * A node in the output tree.
+ */
+class PrintAstNode extends TPrintAstNode {
+  /**
+   * Gets a textual representation of this node.
+   */
+  abstract string toString();
+
+  /**
+   * Gets the child node at index `index`. Child indices must be unique,
+   * but need not be contiguous.
+   */
+  abstract predicate hasChild(PrintAstNode child, int index, string accessor);
+
+  /**
+   * Holds if this node should be printed in the output.
+   */
+  abstract predicate shouldBePrinted();
+
+  /**
+   * Gets the location of this node in the source code.
+   */
+  abstract Location getLocation();
+
+  /**
+   * Gets the value of an additional property of this node, where the name of
+   * the property is `key`.
+   */
+  string getProperty(string key) { none() }
+}
+
+/**
+ * A graph node representing a real Locatable node.
+ */
+class PrintLocatable extends PrintAstNode, TLocatable {
+  Locatable ast;
+
+  PrintLocatable() { this = TLocatable(ast) }
+
+  final override predicate shouldBePrinted() { shouldPrint(ast) }
+
+  override predicate hasChild(PrintAstNode child, int index, string accessor) {
+    child = TLocatable(getChildAndAccessor(ast, index, accessor))
+  }
+
+  override string toString() { result = "[" + concat(ast.getPrimaryQlClasses(), ", ") + "] " + ast }
+
+  final override Location getLocation() { result = ast.getLocation() }
+}

swift/ql/src/queries/ide-contextual-queries/IDEContextual.qll

@@ -0,0 +1,22 @@
+/**
+ * Provides shared predicates related to contextual queries in the code viewer.
+ */
+
+import swift
+
+/**
+ * Returns the `File` matching the given source file name as encoded by the VS
+ * Code extension.
+ */
+cached
+File getFileBySourceArchiveName(string name) {
+  // The name provided for a file in the source archive by the VS Code extension
+  // has some differences from the absolute path in the database:
+  // 1. colons are replaced by underscores
+  // 2. there's a leading slash, even for Windows paths: "C:/foo/bar" ->
+  //    "/C_/foo/bar"
+  // 3. double slashes in UNC prefixes are replaced with a single slash
+  // We can handle 2 and 3 together by unconditionally adding a leading slash
+  // before replacing double slashes.
+  name = ("/" + result.getAbsolutePath().replaceAll(":", "_")).replaceAll("//", "/")
+}

swift/ql/src/queries/ide-contextual-queries/printAst.ql

@@ -0,0 +1,28 @@
+/**
+ * @name Print AST
+ * @description Outputs a representation of a file's Abstract Syntax Tree. This
+ *              query is used by the VS Code extension.
+ * @id swift/print-ast
+ * @kind graph
+ * @tags ide-contextual-queries/print-ast
+ */
+
+import swift
+import codeql.swift.printast.PrintAst
+import IDEContextual
+
+/**
+ * Gets the source file to generate an AST from.
+ */
+external string selectedSourceFile();
+
+class PrintAstConfigurationOverride extends PrintAstConfiguration {
+  /**
+   * Holds if the location matches the selected file in the VS Code extension and
+   * the element is `e`.
+   */
+  override predicate shouldPrint(Locatable e) {
+    super.shouldPrint(e) and
+    e.getFile() = getFileBySourceArchiveName(selectedSourceFile())
+  }
+}