Fix final skipped region not clearing (fixes #61)

 * workaround empty notifications being sent via timer

Author: jackguo380

autoload/lsp_cxx_hl/hl.vim

@@ -92,13 +92,26 @@ function! lsp_cxx_hl#hl#notify_skipped(bufnr, skipped) abort
         if get(b:, 'lsp_cxx_hl_disabled', 0)
             call lsp_cxx_hl#hl#clear()
         else
-            call lsp_cxx_hl#textprop_nvim#skipped#notify(a:bufnr, a:skipped)
+            if !empty(a:skipped)
+                call lsp_cxx_hl#textprop_nvim#skipped#notify(a:bufnr, a:skipped)
+                call s:stop_clear(a:bufnr, 'skipped_clear_timer')
+            else
+                call s:start_clear(a:bufnr, 'skipped_clear_timer',
+                            \ function('lsp_cxx_hl#textprop_nvim#skipped#clear'
+                            \ ))
+            endif
         endif
     elseif g:lsp_cxx_hl_use_text_props
         if get(b:, 'lsp_cxx_hl_disabled', 0)
             call lsp_cxx_hl#hl#clear()
         else
-            call lsp_cxx_hl#textprop#skipped#notify(a:bufnr, a:skipped)
+            if !empty(a:skipped)
+                call lsp_cxx_hl#textprop#skipped#notify(a:bufnr, a:skipped)
+                call s:stop_clear(a:bufnr, 'skipped_clear_timer')
+            else
+                call s:start_clear(a:bufnr, 'skipped_clear_timer',
+                            \ function('lsp_cxx_hl#textprop#skipped#clear'))
+            endif
         endif
     else
         call lsp_cxx_hl#match#skipped#notify(a:bufnr, a:skipped)
@@ -110,3 +123,44 @@ function! lsp_cxx_hl#hl#notify_skipped(bufnr, skipped) abort
         endif
     endif
 endfunction
+
+" Helper for running clear after some time has passed this clears the last
+" symbol or skipped region leftover after a
+" user deletes it
+let s:has_timers = has('timers')
+function! s:start_clear(bufnr, timer_var, ClearFn) abort
+    if !s:has_timers
+        call lsp_cxx_hl#log('WARNING: timers not available, '
+                    \ 'delay cannot be done!')
+        call a:ClearFn()
+        return
+    endif
+
+    let l:timer = getbufvar(a:bufnr, a:timer_var, -1)
+    if l:timer != -1
+        call timer_stop(l:timer)
+    endif
+
+    let l:timer = timer_start(g:lsp_cxx_hl_clear_delay_ms,
+                \ function('s:clear_timer_fn',
+                \ [a:bufnr, a:timer_var, a:ClearFn]))
+    call setbufvar(a:bufnr, a:timer_var, l:timer)
+endfunction
+
+function! s:stop_clear(bufnr, timer_var) abort
+    if !s:has_timers
+        return
+    endif
+
+    let l:timer = getbufvar(a:bufnr, a:timer_var, -1)
+    if l:timer != -1
+        call timer_stop(l:timer)
+    endif
+    call setbufvar(a:bufnr, a:timer_var, -1)
+endfunction
+
+function! s:clear_timer_fn(bufnr, timer_var, ClearFn, timer) abort
+    call lsp_cxx_hl#verbose_log(a:timer_var, ' clear_timer_fn ', l:timer)
+    call a:ClearFn(a:bufnr)
+    call setbufvar(a:bufnr, a:timer_var, -1)
+endfunction

doc/vim-lsp-cxx-highlight.txt

@@ -210,6 +210,22 @@ Default = 0.
   let g:lsp_cxx_hl_light_bg = 1 
 <
 
+-------------------------------------------------------------------------------
+
+                    *lsp_cxx_hl_clear_delay_ms* *g:lsp_cxx_hl_clear_delay_ms*
+g:lsp_cxx_hl_clear_delay_ms
+
+Clear delay for the last remaining skipped region. This is a workaround for
+debouncing erratic empty ccls notifications that appear upon saving.
+
+Generally should be set to longer than it takes to compile the file or else
+highlighting will flash when saving.
+
+Default = 30000.
+>
+  let g:lsp_cxx_hl_clear_delay_ms = 10000
+<
+
 ===============================================================================
 
                                        *vim-lsp-cxx-highlight-highlight-groups*

plugin/vim-lsp-cxx-highlight.vim

@@ -23,6 +23,7 @@ let g:lsp_cxx_hl_use_nvim_text_props = get(g:,
 let g:lsp_cxx_hl_text_prop_refresh_count = get(g:,
             \ 'lsp_cxx_hl_text_prop_refresh_count', 10)
 let g:lsp_cxx_hl_light_bg = get(g:, 'lsp_cxx_hl_light_bg', 0)
+let g:lsp_cxx_hl_clear_delay_ms = get(g:, 'lsp_cxx_hl_clear_delay_ms', 30000)
 
 function s:initialize() abort
     let l:ok = 0