github-copilot-nix/flake.nix at main · jaylabit/github-copilot-nix · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
{
  description = "Nix package for GitHub Copilot CLI";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs = { nixpkgs, ... }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      overlay = final: prev: {
        github-copilot-cli = final.callPackage ./package.nix { };
      };

      forEachSystem =
        f:
        nixpkgs.lib.genAttrs supportedSystems (
          system:
          f (
            import nixpkgs {
              inherit system;
              config.allowUnfree = true;
              overlays = [ overlay ];
            }
          )
        );
    in
    {
      packages = forEachSystem (pkgs: {
        default = pkgs.github-copilot-cli;
        github-copilot-cli = pkgs.github-copilot-cli;
      });

      apps = forEachSystem (pkgs: {
        default = {
          type = "app";
          program = "${pkgs.github-copilot-cli}/bin/copilot";
          meta.description = "Run GitHub Copilot CLI";
        };
        github-copilot-cli = {
          type = "app";
          program = "${pkgs.github-copilot-cli}/bin/copilot";
          meta.description = "Run GitHub Copilot CLI";
        };
      });

      formatter = forEachSystem (pkgs: pkgs.nixfmt);

      devShells = forEachSystem (pkgs: {
        default = pkgs.mkShell {
          packages = with pkgs; [
            curl
            gh
            jq
            nixfmt
          ];
        };
      });

      overlays.default = overlay;
    };
}