Add basic support for properties

See [1]. Does not support property inheritance. Does not support
allowed values. Does not prevent clashes between two keys of different
case, e.g. "key", and "Key". Does not prevent use of special keys.

Keys can only consist of letters a-z and A-Z.

[1] https://orgmode.org/org.html#Properties-and-Columns

Author: aviav

lib/org/document.ex

@@ -102,6 +102,22 @@ defmodule Org.Document do
     %Org.Document{doc | sections: [Org.Section.prepend_content(current_section, content) | rest]}
   end
 
+
+  @doc ~S"""
+  Prepend property to the currently deepest section.
+
+  While preserving order is usually not needed for parsing and
+  interpreting properties, order is still preserved here to e.g. allow
+  re-serialization that preserves line order. This would be desirable
+  e.g. since version control is often based on lines, and works better
+  if there is less noise in the commit history.
+
+  See prepend_content for usage.
+  """
+  def prepend_property(%Org.Document{sections: [current_section | rest]} = doc, property) do
+    %Org.Document{doc | sections: [Org.Section.prepend_property(current_section, property) | rest]}
+  end
+
   @doc ~S"""
   Update the last prepended content. Yields the content to the given updater.
 

lib/org/lexer.ex

@@ -11,7 +11,7 @@ defmodule Org.Lexer do
 
   @type t :: %Org.Lexer{
     tokens: list(token),
-    mode: :normal | :raw
+    mode: :normal | :raw | :property
   }
 
   @moduledoc ~S"""
@@ -58,6 +58,9 @@ defmodule Org.Lexer do
   @section_title_re ~r/^(\*+) (.+)$/
   @empty_line_re    ~r/^\s*$/
   @table_row_re     ~r/^\s*(?:\|[^|]*)+\|\s*$/
+  @begin_props_re   ~r/^\s*\:PROPERTIES\:$/
+  @property_re      ~r/^\s*\:([A-Za-z]+)\:\s*(.+)$/
+  @end_drawer_re    ~r/^\s*\:END\:$/
 
   defp lex_line(line, %Org.Lexer{mode: :normal} = lexer) do
     cond do
@@ -78,6 +81,8 @@ defmodule Org.Lexer do
         |> List.flatten
         |> Enum.map(&String.trim/1)
         append_token(lexer, {:table_row, cells})
+      Regex.run(@begin_props_re, line) ->
+        append_token(lexer, {:begin_drawer, "PROPERTIES"}) |> set_mode(:property)
       true ->
         append_token(lexer, {:text, line})
     end
@@ -91,6 +96,16 @@ defmodule Org.Lexer do
     end
   end
 
+  defp lex_line(line, %Org.Lexer{mode: :property} = lexer) do
+    cond do
+      Regex.run(@end_drawer_re, line) ->
+        append_token(lexer, {:end_drawer}) |> set_mode(:normal)
+      match = Regex.run(@property_re, line) ->
+        [_, key, value] = match
+        append_token(lexer, {:property, key, value})
+    end
+  end
+
   defp append_token(%Org.Lexer{} = lexer, token) do
     %Org.Lexer{lexer | tokens: [token | lexer.tokens]}
   end

lib/org/parser.ex

@@ -3,7 +3,7 @@ defmodule Org.Parser do
 
   @type t :: %Org.Parser{
     doc: Org.Document.t,
-    mode: :paragraph | :table | :code_block | nil,
+    mode: :paragraph | :properties | :table | :code_block | nil,
   }
 
   @moduledoc ~S"""
@@ -88,4 +88,18 @@ defmodule Org.Parser do
   defp parse_token({:end_src}, %Org.Parser{mode: :code_block} = parser) do
     %Org.Parser{parser | mode: nil}
   end
+
+  defp parse_token({:begin_drawer, "PROPERTIES"}, parser) do
+    %Org.Parser{parser | mode: :properties}
+  end
+
+  defp parse_token({:property, key, value}, %Org.Parser{mode: :properties} = parser) do
+    doc = Org.Document.prepend_property(parser.doc, {key |> String.to_atom(), value})
+
+    %Org.Parser{parser | doc: doc}
+  end
+
+  defp parse_token({:end_drawer}, %Org.Parser{mode: :properties} = parser) do
+    %Org.Parser{parser | mode: nil}
+  end
 end

lib/org/section.ex

@@ -1,11 +1,11 @@
 defmodule Org.Section do
-  defstruct title: "", children: [], contents: []
+  defstruct title: "", children: [], contents: [], properties: []
 
   @moduledoc ~S"""
   Represents a section of a document with a title and possible contents & subsections.
 
   Example:
-      iex> source = "* Hello\nWorld\n** What's up?\nNothing much.\n** How's it going?\nAll fine, whow are you?\n"
+      iex> source = "* Hello\nWorld\n** What's up?\n   :PROPERTIES:\n   :Register: non-formal\n   :Intent: inquisitive\n   :END:\nNothing much.\n** How's it going?\nAll fine, whow are you?\n"
       iex> doc = Org.Parser.parse(source)
       iex> section = Org.section(doc, ["Hello"])
       iex> section.contents
@@ -14,12 +14,16 @@ defmodule Org.Section do
       2
       iex> for child <- section.children, do: child.title
       ["What's up?", "How's it going?"]
+      iex> subsection_with_props = Org.section(doc, ["Hello", "What's up?"])
+      iex> subsection_with_props.properties
+      [Register: "non-formal", Intent: "inquisitive"]
   """
 
   @type t :: %Org.Section{
     title: String.t,
     children: list(Org.Section.t),
     contents: list(Org.Content.t),
+    properties: list(Keyword.t),
   }
 
   def add_nested(parent, 1, child) do
@@ -39,6 +43,7 @@ defmodule Org.Section do
       section |
       children: Enum.reverse(Enum.map(section.children, &reverse_recursive/1)),
       contents: Enum.reverse(Enum.map(section.contents, &Org.Content.reverse_recursive/1)),
+      properties: Enum.reverse(section.properties),
     }
   end
 
@@ -82,4 +87,13 @@ defmodule Org.Section do
   def update_content(%Org.Section{children: [current_section | rest]} = section, updater) do
     %Org.Section{section | children: [update_content(current_section, updater) | rest]}
   end
+
+  @doc "Adds property to the last prepended section"
+  def prepend_property(%Org.Section{children: []} = section, property) do
+    %Org.Section{section | properties: [property | section.properties]}
+  end
+
+  def prepend_property(%Org.Section{children: [current_child | children]} = section, property) do
+    %Org.Section{section | children: [prepend_property(current_child, property) | children]}
+  end
 end

test/org/lexer_test.exs

@@ -28,6 +28,13 @@ defmodule Org.LexerTest do
       {:section_title, 2, "another"},
       {:text, "2"},
       {:section_title, 3, "thing"},
+      {:begin_drawer, "PROPERTIES"},
+      {:property, "Title", "Goldberg Variations"},
+      {:property, "Composer", "J.S. Bach"},
+      {:property, "Artist", "Glenn Gould"},
+      {:property, "Publisher", "Deutsche Grammophon"},
+      {:property, "NDisks", "1"},
+      {:end_drawer},
       {:text, "3"},
       {:section_title, 4, "is nesting"},
       {:text, "4"},

test/org/parser_test.exs

@@ -31,5 +31,15 @@ defmodule Org.ParserTest do
         %Org.CodeBlock{lang: "sql", details: "", lines: ["SELECT * FROM products;"]},
       ]
     end
+
+    test "section with properties", %{doc: doc} do
+      assert Org.section(doc, ["Also", "another", "thing"]).properties == [
+        {:Title, "Goldberg Variations"},
+        {:Composer, "J.S. Bach"},
+        {:Artist, "Glenn Gould"},
+        {:Publisher, "Deutsche Grammophon"},
+        {:NDisks, "1"},
+      ]
+    end
   end
 end

test/org_test.exs

@@ -20,6 +20,13 @@ defmodule OrgTest do
   ** another
   2
   *** thing
+      :PROPERTIES:
+      :Title:     Goldberg Variations
+      :Composer:  J.S. Bach
+      :Artist:    Glenn Gould
+      :Publisher: Deutsche Grammophon
+      :NDisks:    1
+      :END:
   3
   **** is nesting
   4