Error: Infinite recursion encountered

[Sigechaishijie]

When I was configuring NixVim, NixOS threw an error:

❯ sudo nixos-rebuild switch
building the system configuration...
error:
       … while calling the 'head' builtin
         at /nix/store/xsdf4r7hl94n1a1kjj02ibs611jnmadn-source/lib/attrsets.nix:1696:13:
         1695|           if length values == 1 || pred here (elemAt values 1) (head values) then
         1696|             head values
             |             ^
         1697|           else

       … while evaluating the attribute 'value'
         at /nix/store/xsdf4r7hl94n1a1kjj02ibs611jnmadn-source/lib/modules.nix:1118:7:
         1117|     // {
         1118|       value = addErrorContext "while evaluating the option `${showOption loc}':" value;
             |       ^
         1119|       inherit (res.defsFinal') highestPrio;

       … while evaluating the option `system.build.toplevel':

       … while evaluating definitions from `/nix/store/xsdf4r7hl94n1a1kjj02ibs611jnmadn-source/nixos/modules/system/activation/top-level.nix':

       … while evaluating the option `assertions':

       … while evaluating definitions from `/nix/store/24j69wckqm02zb7bcyrbxdagyvigw7qn-source/nixos/common.nix':

       … while evaluating the module argument `inputs' in ":anon-4:anon-1":

       … noting that argument `inputs` is not externally provided, so querying `_module.args` instead, requiring `config`

       … if you get an infinite recursion here, you probably reference `config` in `imports`. If you are trying to achieve a conditional import behavior dependent on `config`, consider importing unconditionally, and using `mkEnableOption` and `mkIf` to control its effect.

       (stack trace truncated; use '--show-trace' to show the full, detailed trace)

       error: infinite recursion encountered
Command 'nix --extra-experimental-features 'nix-command flakes' build --print-out-paths '/etc/nixos#nixosConfigurations."Albert-NixOS-PC".config.system.build.toplevel' --no-link' returned non-zero exit status 1.

Here's my configurations:

# flake.nix
{
    description = "Twominus' NixOS configuration";
    inputs = {
        nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
        home-manager = {
            url = "github:nix-community/home-manager";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        nixvim = {
            url = "github:nix-community/nixvim";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        noctalia = {
            url = "github:noctalia-dev/noctalia-shell";
            inputs.nixpkgs.follows = "nixpkgs";
            # inputs.quickshell.follows = "quickshell";
        };
        quickshell = {
            url = "github:outfoxxed/quickshell";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        zen-browser = {
            url = "github:youwen5/zen-browser-flake";
            inputs.nixpkgs.follows = "nixpkgs";
        };
  };

  outputs = inputs@{ self, nixpkgs, home-manager, ... }:
  let
      system = "x86_64-linux";
  in
  {
      nixosConfigurations.Albert-NixOS-PC = nixpkgs.lib.nixosSystem {
          specialArgs = { inherit inputs; };

          modules = [
              ./configuration.nix
              home-manager.nixosModules.home-manager {
                  home-manager.useGlobalPkgs = true;
                  home-manager.useUserPackages = true;
                  home-manager.users.Albert = import ./home.nix;
                  home-manager.extraSpecialArgs = inputs;
                  # Optionally, use home-manager.extraSpecialArgs to pass
                  # arguments to home.nix
              }
          ];
      };
  };
}

# home.nix
{ config, pkgs, inputs, ... }:
{
    imports = [ inputs.nixvim.homeModules.nixvim ];

    home.username = "Albert";
    home.homeDirectory = "/home/Albert";

    home.packages = with pkgs; [
        # CLI
        btop
        cmatrix
        fastfetch

        # Shell
        zim
        zsh

        # Programming
        python

        # Terminal
        ghostty

        # Text
        obsidian
        zed

        # Web
        wget
    ];

    # Git
    programs.git = {
        enable = true;
        settings = {
          user.name = "Twominus";
          user.email = "albert.peng0826@foxmail.com";
        };
    };

    # Libvirt
    # virtualisation.libvirtd = {
    #    enable = true;
    #    qemu.vhostUserPackages = with pkgs; [ virtiofsd ];
    # };

    # NixVim
    programs.nixvim = {
        enable = true;
        config = {
            imports = [ ./home/nixvim ];
        };
    };

    # Virt-manager
    # programs.virt-manager.enable = true;

    home.stateVersion = "26.05";
}

How to fix the problem?

[MattSturgeon]

This shouldn't cause inf-recursion, but the first issue I spotted is:

   programs.nixvim = {
+      imports = [ ./home/nixvim ];
-      enable = true;
       config = {
+          enable = true;
-          imports = [ ./home/nixvim ];
       };
   };

imports is not a config option; it is a special module-system attr that lists other modules to import. enable is a config option, and should be defined under the special module-system attr config to separate it from imports and options.

In this case, you don't actually need to say config. That's usually only needed if you also declare options. When you only have config definitions and imports listed, you can use the "shorthand" module shape:

programs.nixvim = {
  enable = true;
  imports = [ ./home/nixvim ];
};

Two issues here:

  home-manager.nixosModules.home-manager {
      home-manager.useGlobalPkgs = true;
      home-manager.useUserPackages = true;
-     home-manager.users.Albert = import ./home.nix;
+     home-manager.users.Albert = ./home.nix;
-     home-manager.extraSpecialArgs = inputs;
+     home-manager.extraSpecialArgs = { inherit inputs; };
      # Optionally, use home-manager.extraSpecialArgs to pass
      # arguments to home.nix
  }

1. When possible, you should use path-values to refer to modules, instead of importing the nix-expression within the file. Doing this means the module system knows where the module is and can use that in error messages (etc).
2. You should define home-manager.extraSpecialArgs in the same way as specialArgs. You were assigning everything in inputs as lose special args, instead of defining a special arg named inputs.
   This error later causes inf-rec, when you try to use the inputs special arg that you haven't defined.