[Mem2Reg] Complete new enum phi lifetimes.

When multi-block `alloc_stack`s of enum type with users are promoted,
lifetimes of stored values are completed to compensate for the legality
of not `destroy_addr`ing the `alloc_stack` in blocks where no
non-trivial value is known to be stored (the none case block of a
`switch_enum` of a load_borrow of the `alloc_stack`, e.g.).

Here, phis created during promotion are lifetime completed as well.

Author: nate-chandler

lib/SILOptimizer/Transforms/SILMem2Reg.cpp

@@ -1816,6 +1816,12 @@ void StackAllocationPromoter::run() {
   // Use the lifetime completion utility to complete such lifetimes.
   // First, collect the stored values to complete.
   if (asi->getType().isOrHasEnum()) {
+    for (auto *block : livePhiBlocks) {
+      SILPhiArgument *argument = cast<SILPhiArgument>(
+          block->getArgument(block->getNumArguments() - 1));
+      assert(argument->isPhi());
+      valuesToComplete.push_back(argument);
+    }
     for (auto it : initializationPoints) {
       auto *si = it.second;
       auto stored = si->getOperand(CopyLikeInstruction::Src);

test/SILOptimizer/mem2reg_ossa.sil

@@ -610,3 +610,50 @@ bb7:
   return %r : $()
 }
 
+// CHECK-LABEL: sil [ossa] @switch_enum_out_of_new_phi_block : {{.*}} {
+// CHECK-NOT:     alloc_stack
+// CHECK:       } // end sil function 'switch_enum_out_of_new_phi_block'
+sil [ossa] @switch_enum_out_of_new_phi_block : $() -> () {
+entry:
+  %addr = alloc_stack $FakeOptional<Klass>
+  cond_br undef, store_none, agg_either
+
+store_none:
+  %none1 = enum $FakeOptional<Klass>, #FakeOptional.none!enumelt
+  store %none1 to [init] %addr : $*FakeOptional<Klass>
+  br switcheroo
+
+agg_either:
+  cond_br undef, agg_some, agg_none
+
+agg_some:
+  %Klass = apply undef() : $@convention(thin) () -> (@owned Klass)
+  %some = enum $FakeOptional<Klass>, #FakeOptional.some!enumelt, %Klass : $Klass
+  br store_maybe(%some : $FakeOptional<Klass>)
+
+agg_none:
+  %none2 = enum $FakeOptional<Klass>, #FakeOptional.none!enumelt
+  br store_maybe(%none2 : $FakeOptional<Klass>)
+
+store_maybe(%maybe : @owned $FakeOptional<Klass>):
+  store %maybe to [init] %addr : $*FakeOptional<Klass>
+  br switcheroo
+
+switcheroo:
+  %borrow = load_borrow %addr : $*FakeOptional<Klass>
+  switch_enum %borrow : $FakeOptional<Klass>, case #FakeOptional.some!enumelt: bb14, case #FakeOptional.none!enumelt: bb15
+
+bb14(%some_borrowed : @guaranteed $Klass):
+  end_borrow %borrow : $FakeOptional<Klass>
+  destroy_addr %addr : $*FakeOptional<Klass>
+  br bb16
+
+bb15:
+  end_borrow %borrow : $FakeOptional<Klass>
+  br bb16
+
+bb16:
+  dealloc_stack %addr : $*FakeOptional<Klass>
+  %retval = tuple ()
+  return %retval : $()
+}