build: remove C_COMPILE_FLAGS from add_swift_host_library

Use the appropriate CMake mechanism for controlling flags for building
the code.

Author: compnerd

cmake/modules/AddSwift.cmake

@@ -1358,7 +1358,6 @@ endfunction()
 #     [SWIFT_MODULE_DEPENDS dep1 ...]
 #     [LLVM_COMPONENT_DEPENDS comp1 ...]
 #     [FILE_DEPENDS target1 ...]
-#     [C_COMPILE_FLAGS flag1...]
 #     [LINK_FLAGS flag1...]
 #     [INSTALL]
 #     INSTALL_IN_COMPONENT comp
@@ -1382,9 +1381,6 @@ endfunction()
 # FILE_DEPENDS
 #   Additional files this library depends on.
 #
-# C_COMPILE_FLAGS
-#   Extra compiler flags (C, C++, ObjC).
-#
 # LINK_FLAGS
 #   Extra linker flags.
 #
@@ -1415,6 +1411,9 @@ function(add_swift_host_library name)
                         ${ARGN})
   set(ASHL_SOURCES ${ASHL_UNPARSED_ARGUMENTS})
 
+  if(ASHL_C_COMPILE_FLAGS)
+    message(SEND_ERROR "library ${name} is using C_COMPILE_FLAGS parameter which is deprecated.  Please use target_compile_definitions, target_compile_options, or target_include_directories instead")
+  endif()
   if(ASHL_LINK_LIBRARIES)
     message(SEND_ERROR "library ${name} is using LINK_LIBRARIES parameter which is deprecated.  Please use target_link_libraries instead")
   endif()
@@ -1437,7 +1436,6 @@ function(add_swift_host_library name)
     DEPENDS ${ASHL_DEPENDS}
     LLVM_COMPONENT_DEPENDS ${ASHL_LLVM_COMPONENT_DEPENDS}
     FILE_DEPENDS ${ASHL_FILE_DEPENDS}
-    C_COMPILE_FLAGS ${ASHL_C_COMPILE_FLAGS}
     LINK_FLAGS ${ASHL_LINK_FLAGS}
     INTERFACE_LINK_LIBRARIES ${ASHL_INTERFACE_LINK_LIBRARIES}
     INSTALL_IN_COMPONENT "dev"

lib/Basic/CMakeLists.txt

@@ -104,8 +104,9 @@ add_swift_host_library(swiftBasic STATIC
 
   UnicodeExtendedGraphemeClusters.cpp.gyb
 
-  C_COMPILE_FLAGS ${UUID_INCLUDE}
   LLVM_COMPONENT_DEPENDS support)
+target_include_directories(swiftBasic PRIVATE
+  ${UUID_INCLUDE})
 
 if(NOT SWIFT_BUILD_ONLY_SYNTAXPARSERLIB)
   target_link_libraries(swiftBasic PRIVATE

lib/Demangling/CMakeLists.txt

@@ -1,14 +1,13 @@
-add_swift_host_library(swiftDemangling
-                  STATIC
-                    Demangler.cpp
-                    Context.cpp
-                    ManglingUtils.cpp
-                    NodeDumper.cpp
-                    NodePrinter.cpp
-                    OldDemangler.cpp
-                    OldRemangler.cpp
-                    Punycode.cpp
-                    Remangler.cpp
-                  C_COMPILE_FLAGS
-                    -DLLVM_DISABLE_ABI_BREAKING_CHECKS_ENFORCING=1)
+add_swift_host_library(swiftDemangling STATIC
+  Demangler.cpp
+  Context.cpp
+  ManglingUtils.cpp
+  NodeDumper.cpp
+  NodePrinter.cpp
+  OldDemangler.cpp
+  OldRemangler.cpp
+  Punycode.cpp
+  Remangler.cpp)
+target_compile_definitions(swiftDemangling PRIVATE
+  LLVM_DISABLE_ABI_BREAKING_CHECKS_ENFORCING=1)
 

lib/SwiftDemangle/CMakeLists.txt

@@ -1,9 +1,8 @@
-add_swift_host_library(swiftDemangle
-                  SHARED
-                    SwiftDemangle.cpp
-                    MangleHack.cpp
-                  C_COMPILE_FLAGS
-                    -DLLVM_DISABLE_ABI_BREAKING_CHECKS_ENFORCING=1)
+add_swift_host_library(swiftDemangle SHARED
+  SwiftDemangle.cpp
+  MangleHack.cpp)
+target_compile_definitions(swiftDemangle PRIVATE
+  LLVM_DISABLE_ABI_BREAKING_CHECKS_ENFORCING=1)
 target_link_libraries(swiftDemangle PRIVATE
   swiftDemangling)